git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.57)
   5 AC_INIT([libxcb],
   6         1.0,
   7         [xcb@lists.freedesktop.org])
   8 AC_CONFIG_SRCDIR([xcb.pc.in])
   9 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  10
  11 PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
  12 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
  13
  14 AC_CONFIG_HEADERS([src/config.h])
  15
  16 AC_PROG_LIBTOOL
  17 AC_PROG_CC
  18
  19 AC_PATH_PROG(XSLTPROC, xsltproc, no)
  20 if test "$XSLTPROC" = "no"; then
  21    AC_MSG_ERROR([XCB requires xsltproc.])
  22 fi
  23
  24 HTML_CHECK_RESULT=false
  25 if test x"$HAVE_CHECK" = xyes; then
  26         if test x"$XSLTPROC" != xno; then
  27                 HTML_CHECK_RESULT=true
  28         fi
  29 fi
  30 AC_SUBST(HTML_CHECK_RESULT)
  31
  32 # Checks for pkg-config packages
  33 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.0)
  34 NEEDED="xau pthread-stubs"
  35 PKG_CHECK_MODULES(NEEDED, $NEEDED)
  36
  37 have_xdmcp="no"
  38 PKG_CHECK_MODULES(XDMCP, xdmcp,
  39         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  40                 [
  41                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  42                 NEEDED="$NEEDED xdmcp"
  43                 have_xdmcp="yes"
  44                 ],
  45                 [
  46                 XDMCP_CFLAGS=
  47                 XDMCP_LIBS=
  48                 ], [$XDMCP_LIBS]),
  49         [AC_MSG_RESULT(no)])
  50
  51 AC_SUBST(NEEDED)
  52
  53 # Find the xcb-proto protocol descriptions
  54 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  55 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  56 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  57 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  58
  59 AC_HEADER_STDC
  60 AC_SEARCH_LIBS(getaddrinfo, socket)
  61 AC_SEARCH_LIBS(connect, socket)
  62
  63 xcbincludedir='${includedir}/xcb'
  64 AC_SUBST(xcbincludedir)
  65
  66 if  test "x$GCC" = xyes ; then
  67     CWARNFLAGS="-Wall -pedantic -Wpointer-arith \
  68                 -Wstrict-prototypes -Wmissing-declarations -Wnested-externs"
  69 else
  70     AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  71     if test "x$SUNCC" = "xyes"; then
  72         CWARNFLAGS="-v"
  73     fi
  74 fi
  75 AC_SUBST(CWARNFLAGS)
  76
  77 GCC_CHECK_VISIBILITY()
  78
  79 # htmldir is not defined prior to autoconf 2.59c, so on earlier versions
  80 # set an equivalent value.
  81 AC_PREREQ([2.59c], [], [AC_SUBST([htmldir], [m4_ifset([AC_PACKAGE_TARNAME],
  82           ['${datadir}/doc/${PACKAGE_TARNAME}'],
  83           ['${datadir}/doc/${PACKAGE}'])
  84 ])])
  85 AM_CHECK_DOXYGEN()
  86
  87 AC_CONFIG_FILES([Makefile src/Makefile tests/Makefile doc/Makefile])
  88 AC_CONFIG_FILES([xcb.pc xcb-xlib.pc xcb-composite.pc xcb-damage.pc xcb-dpms.pc xcb-glx.pc xcb-randr.pc xcb-record.pc xcb-render.pc xcb-res.pc xcb-screensaver.pc xcb-shape.pc xcb-shm.pc xcb-sync.pc xcb-xevie.pc xcb-xf86dri.pc xcb-xfixes.pc xcb-xinerama.pc xcb-xprint.pc xcb-xtest.pc xcb-xv.pc xcb-xvmc.pc])
  89 AC_CONFIG_FILES([doc/xcb.doxygen])
  90
  91 AC_OUTPUT
  92
  93 dnl Configuration output
  94
  95 echo ""
  96 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
  97 echo ""
  98 echo "  Configuration"
  99 echo "    XDM support.........: ${have_xdmcp}"
 100 echo "    Build unit tests....: ${HAVE_CHECK}"
 101 echo ""
 102 echo "  Used CFLAGS:"
 103 echo "    CPPFLAGS............: ${CPPFLAGS}"
 104 echo "    CFLAGS..............: ${CFLAGS}"
 105 echo "    Warning CFLAGS......: ${CWARNFLAGS}"
 106 echo ""
 107 echo "  Installation:"
 108 echo "    Prefix..............: ${prefix}"
 109 echo ""