git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 # Initialize Autoconf
   4 AC_PREREQ([2.60])
   5 AC_INIT([libxcb],[1.11],
   6         [https://bugs.freedesktop.org/enter_bug.cgi?product=xcb],
   7         [libxcb])
   8 AC_CONFIG_AUX_DIR([build-aux])
   9 AC_CONFIG_MACRO_DIR([m4])
  10 AC_CONFIG_SRCDIR([xcb.pc.in])
  11 AC_CONFIG_HEADERS([src/config.h])
  12
  13 # Initialize Automake
  14 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  15 AM_PATH_PYTHON([2.6])
  16
  17 # Set common system defines for POSIX extensions, such as _GNU_SOURCE
  18 # Must be called before any macros that run the compiler (like AC_PROG_LIBTOOL)
  19 # to avoid autoconf errors.
  20 AC_USE_SYSTEM_EXTENSIONS
  21
  22 # Initialize libtool
  23 LT_PREREQ([2.2])
  24 LT_INIT([win32-dll])
  25
  26 # Require xorg-macros minimum of 1.18 - Initial version
  27 m4_ifndef([XORG_MACROS_VERSION],
  28           [m4_fatal([must install xorg-macros 1.18 or later before running autoconf/autogen])])
  29 XORG_MACROS_VERSION(1.18)
  30 XORG_DEFAULT_OPTIONS
  31 XORG_ENABLE_DEVEL_DOCS
  32 XORG_WITH_DOXYGEN
  33
  34 # The dot drawing tool is checked by XORG_WITH_DOXYGEN, needed for xcb manual
  35 if test x"$HAVE_DOT" = xno; then
  36     AC_MSG_WARN([dot not found - doxygen targets will be skipped])
  37 fi
  38
  39 PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
  40 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
  41
  42 XSLTPROC=no
  43 HTML_CHECK_RESULT=no
  44 if test x"$HAVE_CHECK" = xyes; then
  45         AC_PATH_PROG(XSLTPROC, xsltproc, no)
  46         if test x"$XSLTPROC" != xno; then
  47                 HTML_CHECK_RESULT=yes
  48         fi
  49 fi
  50 AC_SUBST(HTML_CHECK_RESULT)
  51
  52 # Checks for pkg-config packages
  53 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.11)
  54 NEEDED="pthread-stubs xau >= 0.99.2"
  55 PKG_CHECK_MODULES(NEEDED, $NEEDED)
  56
  57 have_xdmcp="no"
  58 PKG_CHECK_MODULES(XDMCP, xdmcp,
  59         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  60                 [
  61                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  62                 NEEDED="$NEEDED xdmcp"
  63                 have_xdmcp="yes"
  64                 ],
  65                 [
  66                 XDMCP_CFLAGS=
  67                 XDMCP_LIBS=
  68                 ], [$XDMCP_LIBS]),
  69         [AC_MSG_RESULT(no)])
  70
  71 AC_SUBST(NEEDED)
  72
  73 # Find the xcb-proto protocol descriptions
  74 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  75 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  76 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  77 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  78
  79 # Find the xcb-proto version
  80 XCBPROTO_VERSION=`$PKG_CONFIG --modversion xcb-proto`
  81 AC_SUBST(XCBPROTO_VERSION)
  82
  83 # Find the xcbgen Python package
  84 AC_MSG_CHECKING(XCBPROTO_XCBPYTHONDIR)
  85 XCBPROTO_XCBPYTHONDIR=`$PKG_CONFIG --variable=pythondir xcb-proto`
  86 AC_MSG_RESULT($XCBPROTO_XCBPYTHONDIR)
  87 AC_SUBST(XCBPROTO_XCBPYTHONDIR)
  88
  89 AC_HEADER_STDC
  90 AC_SEARCH_LIBS(getaddrinfo, socket)
  91 AC_SEARCH_LIBS(connect, socket)
  92
  93 # Find support for sending a message from a socket
  94 AC_SEARCH_LIBS(sendmsg, socket, [have_sendmsg="yes"], [have_sendmsg="no"])
  95
  96 # XPG4v2/UNIX95 added msg_control - check to see if we need to define
  97 # _XOPEN_SOURCE to get it (such as on Solaris)
  98 AC_CHECK_MEMBER([struct msghdr.msg_control], [], [],
  99                  [
 100 AC_INCLUDES_DEFAULT
 101 #include <sys/socket.h>
 102                  ])
 103 # First try for Solaris in C99 compliant mode, which requires XPG6/UNIX03
 104 if test "x$ac_cv_member_struct_msghdr_msg_control" = xno; then
 105     unset ac_cv_member_struct_msghdr_msg_control
 106     AC_MSG_NOTICE([trying again with _XOPEN_SOURCE=600])
 107     AC_CHECK_MEMBER([struct msghdr.msg_control],
 108                     [AC_DEFINE([_XOPEN_SOURCE], [600],
 109                        [Defined if needed to expose struct msghdr.msg_control])
 110                     ], [], [
 111 #define _XOPEN_SOURCE 600
 112 AC_INCLUDES_DEFAULT
 113 #include <sys/socket.h>
 114                      ])
 115 fi
 116 # If that didn't work, fall back to XPG5/UNIX98 with C89
 117 if test "x$ac_cv_member_struct_msghdr_msg_control" = xno; then
 118     unset ac_cv_member_struct_msghdr_msg_control
 119     AC_MSG_NOTICE([trying again with _XOPEN_SOURCE=500])
 120     AC_CHECK_MEMBER([struct msghdr.msg_control],
 121                     [AC_DEFINE([_XOPEN_SOURCE], [500],
 122                        [Defined if needed to expose struct msghdr.msg_control])
 123                     ], [have_sendmsg="no"], [
 124 #define _XOPEN_SOURCE 500
 125 AC_INCLUDES_DEFAULT
 126 #include <sys/socket.h>
 127                      ])
 128 fi
 129
 130 case x$have_sendmsg in
 131 xyes)
 132         AC_DEFINE([HAVE_SENDMSG],1,[Define if your platform supports sendmsg])
 133         ;;
 134 esac
 135
 136 have_win32="no"
 137 lt_enable_auto_import=""
 138 case $host_os in
 139 mingw*)
 140         have_win32="yes"
 141         lt_enable_auto_import="-Wl,--enable-auto-import"
 142         ;;
 143 linux*)
 144         AC_DEFINE([HAVE_ABSTRACT_SOCKETS], 1, [Define if your platform supports abstract sockets])
 145         ;;
 146 esac
 147
 148 AC_SUBST(lt_enable_auto_import)
 149 AM_CONDITIONAL([XCB_HAVE_WIN32], [test "x${have_win32}" = "xyes"])
 150
 151 dnl define buffer queue size
 152 AC_ARG_WITH([queue-size],
 153             AS_HELP_STRING([--with-queue-size=SIZE],
 154             [Set the XCB buffer queue size (default is 16384)]),
 155             [xcb_queue_buffer_size="$withval"],
 156             [xcb_queue_buffer_size=16384])
 157 AC_DEFINE_UNQUOTED(XCB_QUEUE_BUFFER_SIZE, [$xcb_queue_buffer_size],
 158                    [XCB buffer queue size])
 159
 160 dnl check for the sockaddr_un.sun_len member
 161 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 162                 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN,1,[Have the sockaddr_un.sun_len member.])],
 163                 [],
 164                 [ #include <sys/types.h>
 165                   #include <sys/un.h>
 166                 ])
 167
 168 dnl check for support for Solaris Trusted Extensions
 169 AC_CHECK_HEADERS([tsol/label.h])
 170 AC_CHECK_FUNCS([is_system_labeled])
 171
 172 dnl check for IOV_MAX, and fall back to UIO_MAXIOV on BSDish systems
 173 AC_CHECK_DECL([IOV_MAX], [],
 174               [AC_CHECK_DECL([UIO_MAXIOV], [AC_DEFINE([IOV_MAX], [UIO_MAXIOV])],
 175                                            [AC_DEFINE([IOV_MAX], [16], [Define if not provided by <limits.h>])],
 176                                            [[#include <sys/uio.h>]])],
 177               [[#include <limits.h>]])
 178
 179 xcbincludedir='${includedir}/xcb'
 180 AC_SUBST(xcbincludedir)
 181
 182 XCB_CHECK_VISIBILITY()
 183
 184 AC_CHECK_FUNC(getaddrinfo, [AC_DEFINE(HAVE_GETADDRINFO, 1, [getaddrinfo() function is available])], )
 185
 186 case $host_os in
 187         # darwin through Snow Leopard has poll() but can't be used to poll character devices.
 188         darwin@<:@789@:>@*|darwin10*) ;;
 189         darwin*)
 190                 _ac_xorg_macosx_version_min=""
 191                 if echo $CPPFLAGS $CFLAGS | grep -q mmacosx-version-min ; then
 192                         _ac_xorg_macosx_version_min=`echo $CPPFLAGS $CFLAGS | sed 's/^.*-mmacosx-version-min=\(@<:@^ @:>@*\).*$/\1/'`
 193                 else
 194                         _ac_xorg_macosx_version_min=$MACOSX_DEPLOYMENT_TARGET
 195                 fi
 196                 case $_ac_xorg_macosx_version_min in
 197                         10.@<:@0123456@:>@|10.@<:@0123456@:>@.*) ;;
 198                         *)
 199                                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 200                         ;;
 201                 esac
 202                 unset _ac_xorg_macosx_version_min
 203                 ;;
 204         *)
 205                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 206         ;;
 207 esac
 208
 209 XCB_EXTENSION(Composite, yes)
 210 XCB_EXTENSION(Damage, yes)
 211 XCB_EXTENSION(DPMS, yes)
 212 XCB_EXTENSION(DRI2, yes)
 213 XCB_EXTENSION(DRI3, $have_sendmsg)
 214 XCB_EXTENSION(GLX, yes)
 215 XCB_EXTENSION(Present, yes)
 216 XCB_EXTENSION(RandR, yes)
 217 XCB_EXTENSION(Record, yes)
 218 XCB_EXTENSION(Render, yes)
 219 XCB_EXTENSION(Resource, yes)
 220 XCB_EXTENSION(Screensaver, yes)
 221 XCB_EXTENSION(Shape, yes)
 222 XCB_EXTENSION(Shm, yes)
 223 XCB_EXTENSION(Sync, yes)
 224 XCB_EXTENSION(Xevie, no)
 225 XCB_EXTENSION(XFixes, yes)
 226 XCB_EXTENSION(XFree86-DRI, yes)
 227 XCB_EXTENSION(Xinerama, yes)
 228 XCB_EXTENSION(XInput, no)
 229 XCB_EXTENSION(XKB, yes)
 230 XCB_EXTENSION(Xprint, no)
 231 XCB_EXTENSION(SELinux, no)
 232 XCB_EXTENSION(XTest, yes)
 233 XCB_EXTENSION(Xv, yes)
 234 XCB_EXTENSION(XvMC, yes)
 235
 236 AC_ARG_WITH(launchd, AS_HELP_STRING([--with-launchd], [Build with support for Apple's launchd (default: auto)]), [LAUNCHD=$withval], [LAUNCHD=auto])
 237 if test "x$LAUNCHD" = xauto; then
 238         unset LAUNCHD
 239         AC_CHECK_PROG(LAUNCHD, [launchd], [yes], [no], [$PATH$PATH_SEPARATOR/sbin])
 240 fi
 241
 242 if test "x$LAUNCHD" = xyes ; then
 243         AC_DEFINE(HAVE_LAUNCHD, 1, [launchd support available])
 244 fi
 245
 246 AC_CONFIG_FILES([
 247 Makefile
 248 doc/Makefile
 249 man/Makefile
 250 src/Makefile
 251 tests/Makefile
 252 ])
 253
 254 AC_CONFIG_FILES([
 255 xcb.pc
 256 xcb-composite.pc
 257 xcb-damage.pc
 258 xcb-dpms.pc
 259 xcb-dri2.pc
 260 xcb-dri3.pc
 261 xcb-glx.pc
 262 xcb-present.pc
 263 xcb-randr.pc
 264 xcb-record.pc
 265 xcb-render.pc
 266 xcb-res.pc
 267 xcb-screensaver.pc
 268 xcb-shape.pc
 269 xcb-shm.pc
 270 xcb-sync.pc
 271 xcb-xevie.pc
 272 xcb-xf86dri.pc
 273 xcb-xfixes.pc
 274 xcb-xinerama.pc
 275 xcb-xinput.pc
 276 xcb-xkb.pc
 277 xcb-xprint.pc
 278 xcb-xselinux.pc
 279 xcb-xtest.pc
 280 xcb-xv.pc
 281 xcb-xvmc.pc
 282 ])
 283
 284 AC_CONFIG_FILES([
 285 doc/xcb.doxygen
 286 ])
 287
 288 AC_OUTPUT
 289
 290 dnl Configuration output
 291
 292 echo ""
 293 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 294 echo ""
 295 echo "  Configuration"
 296 echo "    XDM support.........: ${have_xdmcp}"
 297 echo "    sendmsg fd passing..: ${have_sendmsg}"
 298 echo "    Build unit tests....: ${HAVE_CHECK}"
 299 echo "      with html results.: ${HTML_CHECK_RESULT}"
 300 echo "    XCB buffer size.....: ${xcb_queue_buffer_size}"
 301 echo ""
 302 echo "  X11 extensions"
 303 echo "    Composite...........: ${BUILD_COMPOSITE}"
 304 echo "    Damage..............: ${BUILD_DAMAGE}"
 305 echo "    Dpms................: ${BUILD_DPMS}"
 306 echo "    Dri2................: ${BUILD_DRI2}"
 307 echo "    Dri3................: ${BUILD_DRI3}"
 308 echo "    Glx.................: ${BUILD_GLX}"
 309 echo "    Randr...............: ${BUILD_RANDR}"
 310 echo "    Record..............: ${BUILD_RECORD}"
 311 echo "    Render..............: ${BUILD_RENDER}"
 312 echo "    Resource............: ${BUILD_RESOURCE}"
 313 echo "    Screensaver.........: ${BUILD_SCREENSAVER}"
 314 echo "    selinux.............: ${BUILD_SELINUX}"
 315 echo "    Shape...............: ${BUILD_SHAPE}"
 316 echo "    Shm.................: ${BUILD_SHM}"
 317 echo "    Sync................: ${BUILD_SYNC}"
 318 echo "    Xevie...............: ${BUILD_XEVIE}"
 319 echo "    Xfixes..............: ${BUILD_XFIXES}"
 320 echo "    Xfree86-dri.........: ${BUILD_XFREE86_DRI}"
 321 echo "    xinerama............: ${BUILD_XINERAMA}"
 322 echo "    xinput..............: ${BUILD_XINPUT}"
 323 echo "    xkb.................: ${BUILD_XKB}"
 324 echo "    xprint..............: ${BUILD_XPRINT}"
 325 echo "    xtest...............: ${BUILD_XTEST}"
 326 echo "    xv..................: ${BUILD_XV}"
 327 echo "    xvmc................: ${BUILD_XVMC}"
 328 echo ""
 329 echo "  Used CFLAGS:"
 330 echo "    CPPFLAGS............: ${CPPFLAGS}"
 331 echo "    CFLAGS..............: ${CFLAGS}"
 332 echo ""
 333 echo "  Installation:"
 334 echo "    Prefix..............: ${prefix}"
 335 echo ""