git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.57)
   5 AC_INIT([libxcb],
   6         1.1.90.1,
   7         [xcb@lists.freedesktop.org])
   8 AC_CONFIG_SRCDIR([xcb.pc.in])
   9 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  10
  11 AM_PATH_PYTHON([2.5])
  12
  13 PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
  14 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
  15
  16 AC_CONFIG_HEADERS([src/config.h])
  17
  18 AC_PROG_LIBTOOL
  19 AC_PROG_CC
  20
  21 AC_PATH_PROG(XSLTPROC, xsltproc, no)
  22 if test "$XSLTPROC" = "no"; then
  23    AC_MSG_ERROR([XCB requires xsltproc.])
  24 fi
  25
  26 HTML_CHECK_RESULT=false
  27 if test x"$HAVE_CHECK" = xyes; then
  28         if test x"$XSLTPROC" != xno; then
  29                 HTML_CHECK_RESULT=true
  30         fi
  31 fi
  32 AC_SUBST(HTML_CHECK_RESULT)
  33
  34 # Checks for pkg-config packages
  35 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.1)
  36 NEEDED="pthread-stubs xau >= 0.99.2"
  37 PKG_CHECK_MODULES(NEEDED, $NEEDED)
  38
  39 have_xdmcp="no"
  40 PKG_CHECK_MODULES(XDMCP, xdmcp,
  41         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  42                 [
  43                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  44                 NEEDED="$NEEDED xdmcp"
  45                 have_xdmcp="yes"
  46                 ],
  47                 [
  48                 XDMCP_CFLAGS=
  49                 XDMCP_LIBS=
  50                 ], [$XDMCP_LIBS]),
  51         [AC_MSG_RESULT(no)])
  52
  53 AC_CHECK_HEADER([execinfo.h], [AC_DEFINE(HAVE_BACKTRACE,1,[Has backtrace*() needed for retrieving stack traces])])
  54
  55 AC_SUBST(NEEDED)
  56
  57 # Find the xcb-proto protocol descriptions
  58 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  59 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  60 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  61 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  62
  63 # Find the xcbgen Python package
  64 AC_MSG_CHECKING(XCBPROTO_XCBPYTHONDIR)
  65 XCBPROTO_XCBPYTHONDIR=`$PKG_CONFIG --variable=pythondir xcb-proto`
  66 AC_MSG_RESULT($XCBPROTO_XCBPYTHONDIR)
  67 AC_SUBST(XCBPROTO_XCBPYTHONDIR)
  68
  69 AC_HEADER_STDC
  70 AC_SEARCH_LIBS(getaddrinfo, socket)
  71 AC_SEARCH_LIBS(connect, socket)
  72
  73 case $host_os in
  74 linux*)
  75         AC_DEFINE([HAVE_ABSTRACT_SOCKETS], 1, [Define if your platform supports abstract sockets])
  76         ;;
  77 esac
  78
  79 dnl define buffer queue size
  80 xcb_queue_buffer_size=16384
  81 AC_DEFINE(XCB_QUEUE_BUFFER_SIZE, $xcb_queue_buffer_size, [XCB buffer queue size])
  82 AC_ARG_WITH(queue-size,
  83             AC_HELP_STRING([--with-queue-size=SIZE],
  84               [Set the XCB buffer queue size (default is 16384)]),
  85             [AC_DEFINE_UNQUOTED(XCB_QUEUE_BUFFER_SIZE, $withval, [XCB buffer queue size]),
  86             xcb_queue_buffer_size=$withval],
  87             )
  88
  89 dnl check for the sockaddr_un.sun_len member
  90 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
  91                 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN,1,[Have the sockaddr_un.sun_len member.])],
  92                 [],
  93                 [ #include <sys/types.h>
  94                   #include <sys/un.h>
  95                 ])
  96
  97 xcbincludedir='${includedir}/xcb'
  98 AC_SUBST(xcbincludedir)
  99
 100 if  test "x$GCC" = xyes ; then
 101     CWARNFLAGS="-Wall -pedantic -Wpointer-arith \
 102                 -Wstrict-prototypes -Wmissing-declarations -Wnested-externs"
 103 else
 104     AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
 105     if test "x$SUNCC" = "xyes"; then
 106         CWARNFLAGS="-v"
 107     fi
 108 fi
 109 AC_SUBST(CWARNFLAGS)
 110
 111 XCB_CHECK_VISIBILITY()
 112
 113 # htmldir is not defined prior to autoconf 2.59c, so on earlier versions
 114 # set an equivalent value.
 115 AC_PREREQ([2.59c], [], [AC_SUBST([htmldir], [m4_ifset([AC_PACKAGE_TARNAME],
 116           ['${datadir}/doc/${PACKAGE_TARNAME}'],
 117           ['${datadir}/doc/${PACKAGE}'])
 118 ])])
 119
 120 XCB_CHECK_DOXYGEN()
 121
 122 XCB_EXTENSION(Composite, "yes")
 123 XCB_EXTENSION(Damage, "yes")
 124 XCB_EXTENSION(DPMS, "yes")
 125 XCB_EXTENSION(GLX, "yes")
 126 XCB_EXTENSION(RandR, "yes")
 127 XCB_EXTENSION(Record, "yes")
 128 XCB_EXTENSION(Render, "yes")
 129 XCB_EXTENSION(Resource, "yes")
 130 XCB_EXTENSION(Screensaver, "yes")
 131 XCB_EXTENSION(Shape, "yes")
 132 XCB_EXTENSION(Shm, "yes")
 133 XCB_EXTENSION(Sync, "yes")
 134 XCB_EXTENSION(Xevie, "yes")
 135 XCB_EXTENSION(XFixes, "yes")
 136 XCB_EXTENSION(XFree86-DRI, "yes")
 137 XCB_EXTENSION(Xinerama, "yes")
 138 XCB_EXTENSION(XInput, "no")
 139 XCB_EXTENSION(Xprint, "yes")
 140 XCB_EXTENSION(SELinux, "no")
 141 XCB_EXTENSION(XTest, "yes")
 142 XCB_EXTENSION(Xv, "yes")
 143 XCB_EXTENSION(XvMC, "yes")
 144
 145
 146 AC_CONFIG_FILES([
 147 Makefile
 148 doc/Makefile
 149 src/Makefile
 150 tests/Makefile
 151 ])
 152
 153 AC_CONFIG_FILES([
 154 xcb.pc
 155 xcb-xlib.pc
 156 xcb-composite.pc
 157 xcb-damage.pc
 158 xcb-dpms.pc
 159 xcb-glx.pc
 160 xcb-randr.pc
 161 xcb-record.pc
 162 xcb-render.pc
 163 xcb-res.pc
 164 xcb-screensaver.pc
 165 xcb-shape.pc
 166 xcb-shm.pc
 167 xcb-sync.pc
 168 xcb-xevie.pc
 169 xcb-xf86dri.pc
 170 xcb-xfixes.pc
 171 xcb-xinerama.pc
 172 xcb-xinput.pc
 173 xcb-xprint.pc
 174 xcb-xselinux.pc
 175 xcb-xtest.pc
 176 xcb-xv.pc
 177 xcb-xvmc.pc
 178 ])
 179
 180 AC_CONFIG_FILES([
 181 doc/xcb.doxygen
 182 ])
 183
 184 AC_OUTPUT
 185
 186 dnl Configuration output
 187
 188 echo ""
 189 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 190 echo ""
 191 echo "  Configuration"
 192 echo "    XDM support.........: ${have_xdmcp}"
 193 echo "    Build unit tests....: ${HAVE_CHECK}"
 194 echo "    XCB buffer size.....: ${xcb_queue_buffer_size}"
 195 echo ""
 196 echo "  Used CFLAGS:"
 197 echo "    CPPFLAGS............: ${CPPFLAGS}"
 198 echo "    CFLAGS..............: ${CFLAGS}"
 199 echo "    Warning CFLAGS......: ${CWARNFLAGS}"
 200 echo ""
 201 echo "  Installation:"
 202 echo "    Prefix..............: ${prefix}"
 203 echo ""