git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Initialize Autoconf
   5 AC_PREREQ([2.60])
   6 AC_INIT([libxcb],
   7         1.9,
   8         [xcb@lists.freedesktop.org])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10 AC_CONFIG_SRCDIR([xcb.pc.in])
  11
  12 # Initialize Automake
  13 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  14 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  15
  16 # Set common system defines for POSIX extensions, such as _GNU_SOURCE
  17 # Must be called before any macros that run the compiler (like AC_PROG_LIBTOOL)
  18 # to avoid autoconf errors.
  19 AC_USE_SYSTEM_EXTENSIONS
  20
  21 AM_PATH_PYTHON([2.6])
  22
  23 PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
  24 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
  25
  26 AC_CONFIG_HEADERS([src/config.h])
  27
  28 AC_LIBTOOL_WIN32_DLL
  29 AC_PROG_LIBTOOL
  30 AC_PROG_CC
  31
  32 XSLTPROC=no
  33 HTML_CHECK_RESULT=no
  34 if test x"$HAVE_CHECK" = xyes; then
  35         AC_PATH_PROG(XSLTPROC, xsltproc, no)
  36         if test x"$XSLTPROC" != xno; then
  37                 HTML_CHECK_RESULT=yes
  38         fi
  39 fi
  40 AC_SUBST(HTML_CHECK_RESULT)
  41
  42 # Checks for pkg-config packages
  43 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.7)
  44 NEEDED="pthread-stubs xau >= 0.99.2"
  45 PKG_CHECK_MODULES(NEEDED, $NEEDED)
  46
  47 have_xdmcp="no"
  48 PKG_CHECK_MODULES(XDMCP, xdmcp,
  49         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  50                 [
  51                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  52                 NEEDED="$NEEDED xdmcp"
  53                 have_xdmcp="yes"
  54                 ],
  55                 [
  56                 XDMCP_CFLAGS=
  57                 XDMCP_LIBS=
  58                 ], [$XDMCP_LIBS]),
  59         [AC_MSG_RESULT(no)])
  60
  61 AC_SUBST(NEEDED)
  62
  63 # Find the xcb-proto protocol descriptions
  64 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  65 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  66 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  67 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  68
  69 # Find the xcb-proto version
  70 XCBPROTO_VERSION=`$PKG_CONFIG --modversion xcb-proto`
  71 AC_SUBST(XCBPROTO_VERSION)
  72
  73 # Find the xcbgen Python package
  74 AC_MSG_CHECKING(XCBPROTO_XCBPYTHONDIR)
  75 XCBPROTO_XCBPYTHONDIR=`$PKG_CONFIG --variable=pythondir xcb-proto`
  76 AC_MSG_RESULT($XCBPROTO_XCBPYTHONDIR)
  77 AC_SUBST(XCBPROTO_XCBPYTHONDIR)
  78
  79 AC_HEADER_STDC
  80 AC_SEARCH_LIBS(getaddrinfo, socket)
  81 AC_SEARCH_LIBS(connect, socket)
  82
  83 have_win32="no"
  84 lt_enable_auto_import=""
  85 case $host_os in
  86 mingw*)
  87         have_win32="yes"
  88         lt_enable_auto_import="-Wl,--enable-auto-import"
  89         ;;
  90 linux*)
  91         AC_DEFINE([HAVE_ABSTRACT_SOCKETS], 1, [Define if your platform supports abstract sockets])
  92         ;;
  93 esac
  94
  95 AC_SUBST(lt_enable_auto_import)
  96 AM_CONDITIONAL([XCB_HAVE_WIN32], [test "x${have_win32}" = "xyes"])
  97
  98 dnl define buffer queue size
  99 AC_ARG_WITH([queue-size],
 100             AC_HELP_STRING([--with-queue-size=SIZE],
 101             [Set the XCB buffer queue size (default is 16384)]),
 102             [xcb_queue_buffer_size="$withval"],
 103             [xcb_queue_buffer_size=16384])
 104 AC_DEFINE_UNQUOTED(XCB_QUEUE_BUFFER_SIZE, [$xcb_queue_buffer_size],
 105                    [XCB buffer queue size])
 106
 107 dnl check for the sockaddr_un.sun_len member
 108 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 109                 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN,1,[Have the sockaddr_un.sun_len member.])],
 110                 [],
 111                 [ #include <sys/types.h>
 112                   #include <sys/un.h>
 113                 ])
 114
 115 dnl check for support for Solaris Trusted Extensions
 116 AC_CHECK_HEADERS([tsol/label.h])
 117 AC_CHECK_FUNCS([is_system_labeled])
 118
 119 dnl check for IOV_MAX, and fall back to UIO_MAXIOV on BSDish systems
 120 AC_CHECK_DECL([IOV_MAX], [],
 121               [AC_CHECK_DECL([UIO_MAXIOV], [AC_DEFINE([IOV_MAX], [UIO_MAXIOV])],
 122                                            [AC_DEFINE([IOV_MAX], [16], [Define if not provided by <limits.h>])],
 123                                            [[#include <sys/uio.h>]])],
 124               [[#include <limits.h>]])
 125
 126 xcbincludedir='${includedir}/xcb'
 127 AC_SUBST(xcbincludedir)
 128
 129 if  test "x$GCC" = xyes ; then
 130     CWARNFLAGS="-Wall -pedantic -Wpointer-arith -Wold-style-definition \
 131                 -Wstrict-prototypes -Wmissing-declarations -Wnested-externs"
 132 else
 133     AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
 134     if test "x$SUNCC" = "xyes"; then
 135         CWARNFLAGS="-v -fd"
 136     fi
 137 fi
 138 AC_SUBST(CWARNFLAGS)
 139
 140 XCB_CHECK_VISIBILITY()
 141
 142 XCB_CHECK_DOXYGEN()
 143
 144 AC_CHECK_FUNC(getaddrinfo, [AC_DEFINE(HAVE_GETADDRINFO, 1, [getaddrinfo() function is available])], )
 145
 146 case $host_os in
 147         # darwin through Snow Leopard has poll() but can't be used to poll character devices.
 148         darwin@<:@789@:>@*|darwin10*) ;;
 149         darwin*)
 150                 _ac_xorg_macosx_version_min=""
 151                 if echo $CPPFLAGS $CFLAGS | grep -q mmacosx-version-min ; then
 152                         _ac_xorg_macosx_version_min=`echo $CPPFLAGS $CFLAGS | sed 's/^.*-mmacosx-version-min=\(@<:@^ @:>@*\).*$/\1/'`
 153                 else
 154                         _ac_xorg_macosx_version_min=$MACOSX_DEPLOYMENT_TARGET
 155                 fi
 156                 case $_ac_xorg_macosx_version_min in
 157                         10.@<:@0123456@:>@|10.@<:@0123456@:>@.*) ;;
 158                         *)
 159                                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 160                         ;;
 161                 esac
 162                 unset _ac_xorg_macosx_version_min
 163                 ;;
 164         *)
 165                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 166         ;;
 167 esac
 168
 169 XCB_EXTENSION(Composite, "yes")
 170 XCB_EXTENSION(Damage, "yes")
 171 XCB_EXTENSION(DPMS, "yes")
 172 XCB_EXTENSION(DRI2, "yes")
 173 XCB_EXTENSION(GLX, "yes")
 174 XCB_EXTENSION(RandR, "yes")
 175 XCB_EXTENSION(Record, "yes")
 176 XCB_EXTENSION(Render, "yes")
 177 XCB_EXTENSION(Resource, "yes")
 178 XCB_EXTENSION(Screensaver, "yes")
 179 XCB_EXTENSION(Shape, "yes")
 180 XCB_EXTENSION(Shm, "yes")
 181 XCB_EXTENSION(Sync, "yes")
 182 XCB_EXTENSION(Xevie, "yes")
 183 XCB_EXTENSION(XFixes, "yes")
 184 XCB_EXTENSION(XFree86-DRI, "yes")
 185 XCB_EXTENSION(Xinerama, "yes")
 186 XCB_EXTENSION(XInput, "no")
 187 XCB_EXTENSION(XKB, "yes")
 188 XCB_EXTENSION(Xprint, "yes")
 189 XCB_EXTENSION(SELinux, "no")
 190 XCB_EXTENSION(XTest, "yes")
 191 XCB_EXTENSION(Xv, "yes")
 192 XCB_EXTENSION(XvMC, "yes")
 193
 194 AC_ARG_WITH(launchd, AS_HELP_STRING([--with-launchd], [Build with support for Apple's launchd (default: auto)]), [LAUNCHD=$withval], [LAUNCHD=auto])
 195 if test "x$LAUNCHD" = xauto; then
 196         unset LAUNCHD
 197         AC_CHECK_PROG(LAUNCHD, [launchd], [yes], [no], [$PATH$PATH_SEPARATOR/sbin])
 198 fi
 199
 200 if test "x$LAUNCHD" = xyes ; then
 201         AC_DEFINE(HAVE_LAUNCHD, 1, [launchd support available])
 202 fi
 203
 204 AC_CONFIG_FILES([
 205 Makefile
 206 doc/Makefile
 207 src/Makefile
 208 tests/Makefile
 209 ])
 210
 211 AC_CONFIG_FILES([
 212 xcb.pc
 213 xcb-composite.pc
 214 xcb-damage.pc
 215 xcb-dpms.pc
 216 xcb-dri2.pc
 217 xcb-glx.pc
 218 xcb-randr.pc
 219 xcb-record.pc
 220 xcb-render.pc
 221 xcb-res.pc
 222 xcb-screensaver.pc
 223 xcb-shape.pc
 224 xcb-shm.pc
 225 xcb-sync.pc
 226 xcb-xevie.pc
 227 xcb-xf86dri.pc
 228 xcb-xfixes.pc
 229 xcb-xinerama.pc
 230 xcb-xinput.pc
 231 xcb-xkb.pc
 232 xcb-xprint.pc
 233 xcb-xselinux.pc
 234 xcb-xtest.pc
 235 xcb-xv.pc
 236 xcb-xvmc.pc
 237 ])
 238
 239 AC_CONFIG_FILES([
 240 doc/xcb.doxygen
 241 ])
 242
 243 AC_OUTPUT
 244
 245 dnl Configuration output
 246
 247 echo ""
 248 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 249 echo ""
 250 echo "  Configuration"
 251 echo "    XDM support.........: ${have_xdmcp}"
 252 echo "    Build unit tests....: ${HAVE_CHECK}"
 253 echo "      with html results.: ${HTML_CHECK_RESULT}"
 254 echo "    XCB buffer size.....: ${xcb_queue_buffer_size}"
 255 echo ""
 256 echo "  X11 extensions"
 257 echo "    Composite...........: ${BUILD_COMPOSITE}"
 258 echo "    Damage..............: ${BUILD_DAMAGE}"
 259 echo "    Dpms................: ${BUILD_DPMS}"
 260 echo "    Dri2................: ${BUILD_DRI2}"
 261 echo "    Glx.................: ${BUILD_GLX}"
 262 echo "    Randr...............: ${BUILD_RANDR}"
 263 echo "    Record..............: ${BUILD_RECORD}"
 264 echo "    Render..............: ${BUILD_RENDER}"
 265 echo "    Resource............: ${BUILD_RESOURCE}"
 266 echo "    Screensaver.........: ${BUILD_SCREENSAVER}"
 267 echo "    selinux.............: ${BUILD_SELINUX}"
 268 echo "    Shape...............: ${BUILD_SHAPE}"
 269 echo "    Shm.................: ${BUILD_SHM}"
 270 echo "    Sync................: ${BUILD_SYNC}"
 271 echo "    Xevie...............: ${BUILD_XEVIE}"
 272 echo "    Xfixes..............: ${BUILD_XFIXES}"
 273 echo "    Xfree86-dri.........: ${BUILD_XFREE86_DRI}"
 274 echo "    xinerama............: ${BUILD_XINERAMA}"
 275 echo "    xinput..............: ${BUILD_XINPUT}"
 276 echo "    xkb.................: ${BUILD_XKB}"
 277 echo "    xprint..............: ${BUILD_XPRINT}"
 278 echo "    xtest...............: ${BUILD_XTEST}"
 279 echo "    xv..................: ${BUILD_XV}"
 280 echo "    xvmc................: ${BUILD_XVMC}"
 281 echo ""
 282 echo "  Used CFLAGS:"
 283 echo "    CPPFLAGS............: ${CPPFLAGS}"
 284 echo "    CFLAGS..............: ${CFLAGS}"
 285 echo "    Warning CFLAGS......: ${CWARNFLAGS}"
 286 echo ""
 287 echo "  Installation:"
 288 echo "    Prefix..............: ${prefix}"
 289 echo ""