git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Initialize Autoconf
   5 AC_PREREQ([2.60])
   6 AC_INIT([libxcb],
   7         1.9,
   8         [xcb@lists.freedesktop.org])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AC_CONFIG_SRCDIR([xcb.pc.in])
  12
  13 # Initialize Automake
  14 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 # Set common system defines for POSIX extensions, such as _GNU_SOURCE
  18 # Must be called before any macros that run the compiler (like AC_PROG_LIBTOOL)
  19 # to avoid autoconf errors.
  20 AC_USE_SYSTEM_EXTENSIONS
  21
  22 AM_PATH_PYTHON([2.6])
  23
  24 PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
  25 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
  26
  27 AC_CONFIG_HEADERS([src/config.h])
  28
  29 AC_LIBTOOL_WIN32_DLL
  30 AC_PROG_LIBTOOL
  31 AC_PROG_CC
  32
  33 XSLTPROC=no
  34 HTML_CHECK_RESULT=no
  35 if test x"$HAVE_CHECK" = xyes; then
  36         AC_PATH_PROG(XSLTPROC, xsltproc, no)
  37         if test x"$XSLTPROC" != xno; then
  38                 HTML_CHECK_RESULT=yes
  39         fi
  40 fi
  41 AC_SUBST(HTML_CHECK_RESULT)
  42
  43 # Checks for pkg-config packages
  44 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.9)
  45 NEEDED="pthread-stubs xau >= 0.99.2"
  46 PKG_CHECK_MODULES(NEEDED, $NEEDED)
  47
  48 have_xdmcp="no"
  49 PKG_CHECK_MODULES(XDMCP, xdmcp,
  50         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  51                 [
  52                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  53                 NEEDED="$NEEDED xdmcp"
  54                 have_xdmcp="yes"
  55                 ],
  56                 [
  57                 XDMCP_CFLAGS=
  58                 XDMCP_LIBS=
  59                 ], [$XDMCP_LIBS]),
  60         [AC_MSG_RESULT(no)])
  61
  62 AC_SUBST(NEEDED)
  63
  64 # Find the xcb-proto protocol descriptions
  65 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  66 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  67 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  68 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  69
  70 # Find the xcb-proto version
  71 XCBPROTO_VERSION=`$PKG_CONFIG --modversion xcb-proto`
  72 AC_SUBST(XCBPROTO_VERSION)
  73
  74 # Find the xcbgen Python package
  75 AC_MSG_CHECKING(XCBPROTO_XCBPYTHONDIR)
  76 XCBPROTO_XCBPYTHONDIR=`$PKG_CONFIG --variable=pythondir xcb-proto`
  77 AC_MSG_RESULT($XCBPROTO_XCBPYTHONDIR)
  78 AC_SUBST(XCBPROTO_XCBPYTHONDIR)
  79
  80 AC_HEADER_STDC
  81 AC_SEARCH_LIBS(getaddrinfo, socket)
  82 AC_SEARCH_LIBS(connect, socket)
  83
  84 AC_ARG_ENABLE(sendfds, AS_HELP_STRING([--disable-sendfds], [Support FD passing (default: auto)]),
  85               [sendfds=$enableval], [sendfds=auto])
  86
  87 case x$sendfds in
  88 xauto)
  89         AC_SEARCH_LIBS(sendmsg, socket, [sendfds="yes"], [sendfds="no"])
  90         ;;
  91 esac
  92
  93 case x$sendfds in
  94 xyes)
  95         AC_DEFINE([HAVE_SENDMSG],1,[Define if your platform supports sendmsg])
  96         ;;
  97 esac
  98
  99 have_win32="no"
 100 lt_enable_auto_import=""
 101 case $host_os in
 102 mingw*)
 103         have_win32="yes"
 104         lt_enable_auto_import="-Wl,--enable-auto-import"
 105         ;;
 106 linux*)
 107         AC_DEFINE([HAVE_ABSTRACT_SOCKETS], 1, [Define if your platform supports abstract sockets])
 108         ;;
 109 esac
 110
 111 AC_SUBST(lt_enable_auto_import)
 112 AM_CONDITIONAL([XCB_HAVE_WIN32], [test "x${have_win32}" = "xyes"])
 113
 114 dnl define buffer queue size
 115 AC_ARG_WITH([queue-size],
 116             AC_HELP_STRING([--with-queue-size=SIZE],
 117             [Set the XCB buffer queue size (default is 16384)]),
 118             [xcb_queue_buffer_size="$withval"],
 119             [xcb_queue_buffer_size=16384])
 120 AC_DEFINE_UNQUOTED(XCB_QUEUE_BUFFER_SIZE, [$xcb_queue_buffer_size],
 121                    [XCB buffer queue size])
 122
 123 dnl check for the sockaddr_un.sun_len member
 124 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 125                 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN,1,[Have the sockaddr_un.sun_len member.])],
 126                 [],
 127                 [ #include <sys/types.h>
 128                   #include <sys/un.h>
 129                 ])
 130
 131 dnl check for support for Solaris Trusted Extensions
 132 AC_CHECK_HEADERS([tsol/label.h])
 133 AC_CHECK_FUNCS([is_system_labeled])
 134
 135 dnl check for IOV_MAX, and fall back to UIO_MAXIOV on BSDish systems
 136 AC_CHECK_DECL([IOV_MAX], [],
 137               [AC_CHECK_DECL([UIO_MAXIOV], [AC_DEFINE([IOV_MAX], [UIO_MAXIOV])],
 138                                            [AC_DEFINE([IOV_MAX], [16], [Define if not provided by <limits.h>])],
 139                                            [[#include <sys/uio.h>]])],
 140               [[#include <limits.h>]])
 141
 142 xcbincludedir='${includedir}/xcb'
 143 AC_SUBST(xcbincludedir)
 144
 145 if  test "x$GCC" = xyes ; then
 146     CWARNFLAGS="-Wall -Wpointer-arith -Wold-style-definition \
 147                 -Wstrict-prototypes -Wmissing-declarations -Wnested-externs"
 148 else
 149     AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
 150     if test "x$SUNCC" = "xyes"; then
 151         CWARNFLAGS="-v -fd"
 152     fi
 153 fi
 154 AC_SUBST(CWARNFLAGS)
 155
 156 XCB_CHECK_VISIBILITY()
 157
 158 XCB_CHECK_DOXYGEN()
 159
 160 AC_CHECK_FUNC(getaddrinfo, [AC_DEFINE(HAVE_GETADDRINFO, 1, [getaddrinfo() function is available])], )
 161
 162 case $host_os in
 163         # darwin through Snow Leopard has poll() but can't be used to poll character devices.
 164         darwin@<:@789@:>@*|darwin10*) ;;
 165         darwin*)
 166                 _ac_xorg_macosx_version_min=""
 167                 if echo $CPPFLAGS $CFLAGS | grep -q mmacosx-version-min ; then
 168                         _ac_xorg_macosx_version_min=`echo $CPPFLAGS $CFLAGS | sed 's/^.*-mmacosx-version-min=\(@<:@^ @:>@*\).*$/\1/'`
 169                 else
 170                         _ac_xorg_macosx_version_min=$MACOSX_DEPLOYMENT_TARGET
 171                 fi
 172                 case $_ac_xorg_macosx_version_min in
 173                         10.@<:@0123456@:>@|10.@<:@0123456@:>@.*) ;;
 174                         *)
 175                                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 176                         ;;
 177                 esac
 178                 unset _ac_xorg_macosx_version_min
 179                 ;;
 180         *)
 181                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 182         ;;
 183 esac
 184
 185 XCB_EXTENSION(Composite, "yes")
 186 XCB_EXTENSION(Damage, "yes")
 187 XCB_EXTENSION(DPMS, "yes")
 188 XCB_EXTENSION(DRI2, "yes")
 189 XCB_EXTENSION(DRI3, "$sendfds")
 190 XCB_EXTENSION(GLX, "yes")
 191 XCB_EXTENSION(Present, "yes")
 192 XCB_EXTENSION(RandR, "yes")
 193 XCB_EXTENSION(Record, "yes")
 194 XCB_EXTENSION(Render, "yes")
 195 XCB_EXTENSION(Resource, "yes")
 196 XCB_EXTENSION(Screensaver, "yes")
 197 XCB_EXTENSION(Shape, "yes")
 198 XCB_EXTENSION(Shm, "yes")
 199 XCB_EXTENSION(Sync, "yes")
 200 XCB_EXTENSION(Xevie, "yes")
 201 XCB_EXTENSION(XFixes, "yes")
 202 XCB_EXTENSION(XFree86-DRI, "yes")
 203 XCB_EXTENSION(Xinerama, "yes")
 204 XCB_EXTENSION(XInput, "no")
 205 XCB_EXTENSION(XKB, "yes")
 206 XCB_EXTENSION(Xprint, "yes")
 207 XCB_EXTENSION(SELinux, "no")
 208 XCB_EXTENSION(XTest, "yes")
 209 XCB_EXTENSION(Xv, "yes")
 210 XCB_EXTENSION(XvMC, "yes")
 211
 212 AC_ARG_WITH(launchd, AS_HELP_STRING([--with-launchd], [Build with support for Apple's launchd (default: auto)]), [LAUNCHD=$withval], [LAUNCHD=auto])
 213 if test "x$LAUNCHD" = xauto; then
 214         unset LAUNCHD
 215         AC_CHECK_PROG(LAUNCHD, [launchd], [yes], [no], [$PATH$PATH_SEPARATOR/sbin])
 216 fi
 217
 218 if test "x$LAUNCHD" = xyes ; then
 219         AC_DEFINE(HAVE_LAUNCHD, 1, [launchd support available])
 220 fi
 221
 222 AC_CONFIG_FILES([
 223 Makefile
 224 doc/Makefile
 225 src/Makefile
 226 tests/Makefile
 227 ])
 228
 229 AC_CONFIG_FILES([
 230 xcb.pc
 231 xcb-composite.pc
 232 xcb-damage.pc
 233 xcb-dpms.pc
 234 xcb-dri2.pc
 235 xcb-dri3.pc
 236 xcb-glx.pc
 237 xcb-present.pc
 238 xcb-randr.pc
 239 xcb-record.pc
 240 xcb-render.pc
 241 xcb-res.pc
 242 xcb-screensaver.pc
 243 xcb-shape.pc
 244 xcb-shm.pc
 245 xcb-sync.pc
 246 xcb-xevie.pc
 247 xcb-xf86dri.pc
 248 xcb-xfixes.pc
 249 xcb-xinerama.pc
 250 xcb-xinput.pc
 251 xcb-xkb.pc
 252 xcb-xprint.pc
 253 xcb-xselinux.pc
 254 xcb-xtest.pc
 255 xcb-xv.pc
 256 xcb-xvmc.pc
 257 ])
 258
 259 AC_CONFIG_FILES([
 260 doc/xcb.doxygen
 261 ])
 262
 263 AC_OUTPUT
 264
 265 dnl Configuration output
 266
 267 echo ""
 268 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 269 echo ""
 270 echo "  Configuration"
 271 echo "    XDM support.........: ${have_xdmcp}"
 272 echo "    sendmsg fd passing..: ${sendfds}"
 273 echo "    Build unit tests....: ${HAVE_CHECK}"
 274 echo "      with html results.: ${HTML_CHECK_RESULT}"
 275 echo "    XCB buffer size.....: ${xcb_queue_buffer_size}"
 276 echo ""
 277 echo "  X11 extensions"
 278 echo "    Composite...........: ${BUILD_COMPOSITE}"
 279 echo "    Damage..............: ${BUILD_DAMAGE}"
 280 echo "    Dpms................: ${BUILD_DPMS}"
 281 echo "    Dri2................: ${BUILD_DRI2}"
 282 echo "    Dri3................: ${BUILD_DRI3}"
 283 echo "    Glx.................: ${BUILD_GLX}"
 284 echo "    Randr...............: ${BUILD_RANDR}"
 285 echo "    Record..............: ${BUILD_RECORD}"
 286 echo "    Render..............: ${BUILD_RENDER}"
 287 echo "    Resource............: ${BUILD_RESOURCE}"
 288 echo "    Screensaver.........: ${BUILD_SCREENSAVER}"
 289 echo "    selinux.............: ${BUILD_SELINUX}"
 290 echo "    Shape...............: ${BUILD_SHAPE}"
 291 echo "    Shm.................: ${BUILD_SHM}"
 292 echo "    Sync................: ${BUILD_SYNC}"
 293 echo "    Xevie...............: ${BUILD_XEVIE}"
 294 echo "    Xfixes..............: ${BUILD_XFIXES}"
 295 echo "    Xfree86-dri.........: ${BUILD_XFREE86_DRI}"
 296 echo "    xinerama............: ${BUILD_XINERAMA}"
 297 echo "    xinput..............: ${BUILD_XINPUT}"
 298 echo "    xkb.................: ${BUILD_XKB}"
 299 echo "    xprint..............: ${BUILD_XPRINT}"
 300 echo "    xtest...............: ${BUILD_XTEST}"
 301 echo "    xv..................: ${BUILD_XV}"
 302 echo "    xvmc................: ${BUILD_XVMC}"
 303 echo ""
 304 echo "  Used CFLAGS:"
 305 echo "    CPPFLAGS............: ${CPPFLAGS}"
 306 echo "    CFLAGS..............: ${CFLAGS}"
 307 echo "    Warning CFLAGS......: ${CWARNFLAGS}"
 308 echo ""
 309 echo "  Installation:"
 310 echo "    Prefix..............: ${prefix}"
 311 echo ""