git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.57)
   5 AC_INIT([libxcb],
   6         1.7,
   7         [xcb@lists.freedesktop.org])
   8 AC_CONFIG_SRCDIR([xcb.pc.in])
   9 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  10
  11 AM_PATH_PYTHON([2.5])
  12
  13 PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
  14 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
  15
  16 AC_CONFIG_HEADERS([src/config.h])
  17
  18 AC_LIBTOOL_WIN32_DLL
  19 AC_PROG_LIBTOOL
  20 AC_PROG_CC
  21
  22 AC_PATH_PROG(XSLTPROC, xsltproc, no)
  23 if test "$XSLTPROC" = "no"; then
  24    AC_MSG_ERROR([XCB requires xsltproc.])
  25 fi
  26
  27 HTML_CHECK_RESULT=false
  28 if test x"$HAVE_CHECK" = xyes; then
  29         if test x"$XSLTPROC" != xno; then
  30                 HTML_CHECK_RESULT=true
  31         fi
  32 fi
  33 AC_SUBST(HTML_CHECK_RESULT)
  34
  35 # Checks for pkg-config packages
  36 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.6)
  37 NEEDED="pthread-stubs xau >= 0.99.2"
  38 PKG_CHECK_MODULES(NEEDED, $NEEDED)
  39
  40 have_xdmcp="no"
  41 PKG_CHECK_MODULES(XDMCP, xdmcp,
  42         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  43                 [
  44                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  45                 NEEDED="$NEEDED xdmcp"
  46                 have_xdmcp="yes"
  47                 ],
  48                 [
  49                 XDMCP_CFLAGS=
  50                 XDMCP_LIBS=
  51                 ], [$XDMCP_LIBS]),
  52         [AC_MSG_RESULT(no)])
  53
  54 AC_SUBST(NEEDED)
  55
  56 # Find the xcb-proto protocol descriptions
  57 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  58 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  59 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  60 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  61
  62 # Find the xcb-proto version
  63 XCBPROTO_VERSION=`$PKG_CONFIG --modversion xcb-proto`
  64 AC_SUBST(XCBPROTO_VERSION)
  65
  66 # Find the xcbgen Python package
  67 AC_MSG_CHECKING(XCBPROTO_XCBPYTHONDIR)
  68 XCBPROTO_XCBPYTHONDIR=`$PKG_CONFIG --variable=pythondir xcb-proto`
  69 AC_MSG_RESULT($XCBPROTO_XCBPYTHONDIR)
  70 AC_SUBST(XCBPROTO_XCBPYTHONDIR)
  71
  72 AC_HEADER_STDC
  73 AC_SEARCH_LIBS(getaddrinfo, socket)
  74 AC_SEARCH_LIBS(connect, socket)
  75
  76 have_win32="no"
  77 lt_enable_auto_import=""
  78 case $host_os in
  79 mingw*)
  80         have_win32="yes"
  81         lt_enable_auto_import="-Wl,--enable-auto-import"
  82         ;;
  83 linux*)
  84         AC_DEFINE([HAVE_ABSTRACT_SOCKETS], 1, [Define if your platform supports abstract sockets])
  85         ;;
  86 esac
  87
  88 AC_SUBST(lt_enable_auto_import)
  89 AM_CONDITIONAL([XCB_HAVE_WIN32], [test "x${have_win32}" = "xyes"])
  90
  91 dnl define buffer queue size
  92 AC_ARG_WITH([queue-size],
  93             AC_HELP_STRING([--with-queue-size=SIZE],
  94             [Set the XCB buffer queue size (default is 16384)]),
  95             [xcb_queue_buffer_size="$withval"],
  96             [xcb_queue_buffer_size=16384])
  97 AC_DEFINE_UNQUOTED(XCB_QUEUE_BUFFER_SIZE, [$xcb_queue_buffer_size],
  98                    [XCB buffer queue size])
  99
 100 dnl check for the sockaddr_un.sun_len member
 101 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 102                 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN,1,[Have the sockaddr_un.sun_len member.])],
 103                 [],
 104                 [ #include <sys/types.h>
 105                   #include <sys/un.h>
 106                 ])
 107
 108 xcbincludedir='${includedir}/xcb'
 109 AC_SUBST(xcbincludedir)
 110
 111 if  test "x$GCC" = xyes ; then
 112     CWARNFLAGS="-Wall -pedantic -Wpointer-arith \
 113                 -Wstrict-prototypes -Wmissing-declarations -Wnested-externs"
 114 else
 115     AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
 116     if test "x$SUNCC" = "xyes"; then
 117         CWARNFLAGS="-v"
 118     fi
 119 fi
 120 AC_SUBST(CWARNFLAGS)
 121
 122 XCB_CHECK_VISIBILITY()
 123
 124 # htmldir is not defined prior to autoconf 2.59c, so on earlier versions
 125 # set an equivalent value.
 126 AC_PREREQ([2.59c], [], [AC_SUBST([htmldir], [m4_ifset([AC_PACKAGE_TARNAME],
 127           ['${datadir}/doc/${PACKAGE_TARNAME}'],
 128           ['${datadir}/doc/${PACKAGE}'])
 129 ])])
 130
 131 XCB_CHECK_DOXYGEN()
 132
 133 case $host_os in
 134         # darwin has poll() but can't be used to poll character devices (atleast through SnowLeopard)
 135         darwin*) ;;
 136         *)
 137                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 138         ;;
 139 esac
 140
 141 XCB_EXTENSION(Composite, "yes")
 142 XCB_EXTENSION(Damage, "yes")
 143 XCB_EXTENSION(DPMS, "yes")
 144 XCB_EXTENSION(DRI2, "yes")
 145 XCB_EXTENSION(GLX, "yes")
 146 XCB_EXTENSION(RandR, "yes")
 147 XCB_EXTENSION(Record, "yes")
 148 XCB_EXTENSION(Render, "yes")
 149 XCB_EXTENSION(Resource, "yes")
 150 XCB_EXTENSION(Screensaver, "yes")
 151 XCB_EXTENSION(Shape, "yes")
 152 XCB_EXTENSION(Shm, "yes")
 153 XCB_EXTENSION(Sync, "yes")
 154 XCB_EXTENSION(Xevie, "yes")
 155 XCB_EXTENSION(XFixes, "yes")
 156 XCB_EXTENSION(XFree86-DRI, "yes")
 157 XCB_EXTENSION(Xinerama, "yes")
 158 XCB_EXTENSION(XInput, "no")
 159 XCB_EXTENSION(XKB, "no")
 160 XCB_EXTENSION(Xprint, "yes")
 161 XCB_EXTENSION(SELinux, "no")
 162 XCB_EXTENSION(XTest, "yes")
 163 XCB_EXTENSION(Xv, "yes")
 164 XCB_EXTENSION(XvMC, "yes")
 165
 166 AC_ARG_WITH(launchd, AS_HELP_STRING([--with-launchd], [Build with support for Apple's launchd (default: auto)]), [LAUNCHD=$withval], [LAUNCHD=auto])
 167 if test "x$LAUNCHD" = xauto; then
 168         unset LAUNCHD
 169         AC_CHECK_PROG(LAUNCHD, [launchd], [yes], [no], [$PATH$PATH_SEPARATOR/sbin])
 170 fi
 171
 172 if test "x$LAUNCHD" = xyes ; then
 173         AC_DEFINE(HAVE_LAUNCHD, 1, [launchd support available])
 174 fi
 175
 176 AC_CONFIG_FILES([
 177 Makefile
 178 doc/Makefile
 179 src/Makefile
 180 tests/Makefile
 181 ])
 182
 183 AC_CONFIG_FILES([
 184 xcb.pc
 185 xcb-composite.pc
 186 xcb-damage.pc
 187 xcb-dpms.pc
 188 xcb-dri2.pc
 189 xcb-glx.pc
 190 xcb-randr.pc
 191 xcb-record.pc
 192 xcb-render.pc
 193 xcb-res.pc
 194 xcb-screensaver.pc
 195 xcb-shape.pc
 196 xcb-shm.pc
 197 xcb-sync.pc
 198 xcb-xevie.pc
 199 xcb-xf86dri.pc
 200 xcb-xfixes.pc
 201 xcb-xinerama.pc
 202 xcb-xinput.pc
 203 xcb-xkb.pc
 204 xcb-xprint.pc
 205 xcb-xselinux.pc
 206 xcb-xtest.pc
 207 xcb-xv.pc
 208 xcb-xvmc.pc
 209 ])
 210
 211 AC_CONFIG_FILES([
 212 doc/xcb.doxygen
 213 ])
 214
 215 AC_OUTPUT
 216
 217 dnl Configuration output
 218
 219 echo ""
 220 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 221 echo ""
 222 echo "  Configuration"
 223 echo "    XDM support.........: ${have_xdmcp}"
 224 echo "    Build unit tests....: ${HAVE_CHECK}"
 225 echo "    XCB buffer size.....: ${xcb_queue_buffer_size}"
 226 echo ""
 227 echo "  X11 extensions"
 228 echo "    Composite...........: ${BUILD_COMPOSITE}"
 229 echo "    Damage..............: ${BUILD_DAMAGE}"
 230 echo "    Dpms................: ${BUILD_DPMS}"
 231 echo "    Dri2................: ${BUILD_DRI2}"
 232 echo "    Glx.................: ${BUILD_GLX}"
 233 echo "    Randr...............: ${BUILD_RANDR}"
 234 echo "    Record..............: ${BUILD_RECORD}"
 235 echo "    Render..............: ${BUILD_RENDER}"
 236 echo "    Resource............: ${BUILD_RESOURCE}"
 237 echo "    Screensaver.........: ${BUILD_SCREENSAVER}"
 238 echo "    selinux.............: ${BUILD_SELINUX}"
 239 echo "    Shape...............: ${BUILD_SHAPE}"
 240 echo "    Shm.................: ${BUILD_SHM}"
 241 echo "    Sync................: ${BUILD_SYNC}"
 242 echo "    Xevie...............: ${BUILD_XEVIE}"
 243 echo "    Xfixes..............: ${BUILD_XFIXES}"
 244 echo "    Xfree86-dri.........: ${BUILD_XFREE86_DRI}"
 245 echo "    xinerama............: ${BUILD_XINERAMA}"
 246 echo "    xinput..............: ${BUILD_XINPUT}"
 247 echo "    xprint..............: ${BUILD_XPRINT}"
 248 echo "    xtest...............: ${BUILD_XTEST}"
 249 echo "    xv..................: ${BUILD_XV}"
 250 echo "    xvmc................: ${BUILD_XVMC}"
 251 echo ""
 252 echo "  Used CFLAGS:"
 253 echo "    CPPFLAGS............: ${CPPFLAGS}"
 254 echo "    CFLAGS..............: ${CFLAGS}"
 255 echo "    Warning CFLAGS......: ${CWARNFLAGS}"
 256 echo ""
 257 echo "  Installation:"
 258 echo "    Prefix..............: ${prefix}"
 259 echo ""