git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Initialize Autoconf
   5 AC_PREREQ([2.60])
   6 AC_INIT([libxcb],
   7         1.9,
   8         [xcb@lists.freedesktop.org])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AC_CONFIG_SRCDIR([xcb.pc.in])
  12
  13 # Initialize Automake
  14 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 # Set common system defines for POSIX extensions, such as _GNU_SOURCE
  18 # Must be called before any macros that run the compiler (like AC_PROG_LIBTOOL)
  19 # to avoid autoconf errors.
  20 AC_USE_SYSTEM_EXTENSIONS
  21
  22 AM_PATH_PYTHON([2.6])
  23
  24 PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
  25 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
  26
  27 AC_CONFIG_HEADERS([src/config.h])
  28
  29 AC_LIBTOOL_WIN32_DLL
  30 AC_PROG_LIBTOOL
  31 AC_PROG_CC
  32
  33 XSLTPROC=no
  34 HTML_CHECK_RESULT=no
  35 if test x"$HAVE_CHECK" = xyes; then
  36         AC_PATH_PROG(XSLTPROC, xsltproc, no)
  37         if test x"$XSLTPROC" != xno; then
  38                 HTML_CHECK_RESULT=yes
  39         fi
  40 fi
  41 AC_SUBST(HTML_CHECK_RESULT)
  42
  43 # Checks for pkg-config packages
  44 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.7)
  45 NEEDED="pthread-stubs xau >= 0.99.2"
  46 PKG_CHECK_MODULES(NEEDED, $NEEDED)
  47
  48 have_xdmcp="no"
  49 PKG_CHECK_MODULES(XDMCP, xdmcp,
  50         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  51                 [
  52                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  53                 NEEDED="$NEEDED xdmcp"
  54                 have_xdmcp="yes"
  55                 ],
  56                 [
  57                 XDMCP_CFLAGS=
  58                 XDMCP_LIBS=
  59                 ], [$XDMCP_LIBS]),
  60         [AC_MSG_RESULT(no)])
  61
  62 AC_SUBST(NEEDED)
  63
  64 # Find the xcb-proto protocol descriptions
  65 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  66 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  67 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  68 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  69
  70 # Find the xcb-proto version
  71 XCBPROTO_VERSION=`$PKG_CONFIG --modversion xcb-proto`
  72 AC_SUBST(XCBPROTO_VERSION)
  73
  74 # Find the xcbgen Python package
  75 AC_MSG_CHECKING(XCBPROTO_XCBPYTHONDIR)
  76 XCBPROTO_XCBPYTHONDIR=`$PKG_CONFIG --variable=pythondir xcb-proto`
  77 AC_MSG_RESULT($XCBPROTO_XCBPYTHONDIR)
  78 AC_SUBST(XCBPROTO_XCBPYTHONDIR)
  79
  80 AC_HEADER_STDC
  81 AC_SEARCH_LIBS(getaddrinfo, socket)
  82 AC_SEARCH_LIBS(connect, socket)
  83
  84 have_win32="no"
  85 lt_enable_auto_import=""
  86 case $host_os in
  87 mingw*)
  88         have_win32="yes"
  89         lt_enable_auto_import="-Wl,--enable-auto-import"
  90         ;;
  91 linux*)
  92         AC_DEFINE([HAVE_ABSTRACT_SOCKETS], 1, [Define if your platform supports abstract sockets])
  93         ;;
  94 esac
  95
  96 AC_SUBST(lt_enable_auto_import)
  97 AM_CONDITIONAL([XCB_HAVE_WIN32], [test "x${have_win32}" = "xyes"])
  98
  99 dnl define buffer queue size
 100 AC_ARG_WITH([queue-size],
 101             AC_HELP_STRING([--with-queue-size=SIZE],
 102             [Set the XCB buffer queue size (default is 16384)]),
 103             [xcb_queue_buffer_size="$withval"],
 104             [xcb_queue_buffer_size=16384])
 105 AC_DEFINE_UNQUOTED(XCB_QUEUE_BUFFER_SIZE, [$xcb_queue_buffer_size],
 106                    [XCB buffer queue size])
 107
 108 dnl check for the sockaddr_un.sun_len member
 109 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 110                 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN,1,[Have the sockaddr_un.sun_len member.])],
 111                 [],
 112                 [ #include <sys/types.h>
 113                   #include <sys/un.h>
 114                 ])
 115
 116 dnl check for support for Solaris Trusted Extensions
 117 AC_CHECK_HEADERS([tsol/label.h])
 118 AC_CHECK_FUNCS([is_system_labeled])
 119
 120 dnl check for IOV_MAX, and fall back to UIO_MAXIOV on BSDish systems
 121 AC_CHECK_DECL([IOV_MAX], [],
 122               [AC_CHECK_DECL([UIO_MAXIOV], [AC_DEFINE([IOV_MAX], [UIO_MAXIOV])],
 123                                            [AC_DEFINE([IOV_MAX], [16], [Define if not provided by <limits.h>])],
 124                                            [[#include <sys/uio.h>]])],
 125               [[#include <limits.h>]])
 126
 127 xcbincludedir='${includedir}/xcb'
 128 AC_SUBST(xcbincludedir)
 129
 130 if  test "x$GCC" = xyes ; then
 131     CWARNFLAGS="-Wall -Wpointer-arith -Wold-style-definition \
 132                 -Wstrict-prototypes -Wmissing-declarations -Wnested-externs"
 133 else
 134     AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
 135     if test "x$SUNCC" = "xyes"; then
 136         CWARNFLAGS="-v -fd"
 137     fi
 138 fi
 139 AC_SUBST(CWARNFLAGS)
 140
 141 XCB_CHECK_VISIBILITY()
 142
 143 XCB_CHECK_DOXYGEN()
 144
 145 AC_CHECK_FUNC(getaddrinfo, [AC_DEFINE(HAVE_GETADDRINFO, 1, [getaddrinfo() function is available])], )
 146
 147 case $host_os in
 148         # darwin through Snow Leopard has poll() but can't be used to poll character devices.
 149         darwin@<:@789@:>@*|darwin10*) ;;
 150         darwin*)
 151                 _ac_xorg_macosx_version_min=""
 152                 if echo $CPPFLAGS $CFLAGS | grep -q mmacosx-version-min ; then
 153                         _ac_xorg_macosx_version_min=`echo $CPPFLAGS $CFLAGS | sed 's/^.*-mmacosx-version-min=\(@<:@^ @:>@*\).*$/\1/'`
 154                 else
 155                         _ac_xorg_macosx_version_min=$MACOSX_DEPLOYMENT_TARGET
 156                 fi
 157                 case $_ac_xorg_macosx_version_min in
 158                         10.@<:@0123456@:>@|10.@<:@0123456@:>@.*) ;;
 159                         *)
 160                                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 161                         ;;
 162                 esac
 163                 unset _ac_xorg_macosx_version_min
 164                 ;;
 165         *)
 166                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 167         ;;
 168 esac
 169
 170 XCB_EXTENSION(Composite, "yes")
 171 XCB_EXTENSION(Damage, "yes")
 172 XCB_EXTENSION(DPMS, "yes")
 173 XCB_EXTENSION(DRI2, "yes")
 174 XCB_EXTENSION(GLX, "yes")
 175 XCB_EXTENSION(RandR, "yes")
 176 XCB_EXTENSION(Record, "yes")
 177 XCB_EXTENSION(Render, "yes")
 178 XCB_EXTENSION(Resource, "yes")
 179 XCB_EXTENSION(Screensaver, "yes")
 180 XCB_EXTENSION(Shape, "yes")
 181 XCB_EXTENSION(Shm, "yes")
 182 XCB_EXTENSION(Sync, "yes")
 183 XCB_EXTENSION(Xevie, "yes")
 184 XCB_EXTENSION(XFixes, "yes")
 185 XCB_EXTENSION(XFree86-DRI, "yes")
 186 XCB_EXTENSION(Xinerama, "yes")
 187 XCB_EXTENSION(XInput, "no")
 188 XCB_EXTENSION(XKB, "yes")
 189 XCB_EXTENSION(Xprint, "yes")
 190 XCB_EXTENSION(SELinux, "no")
 191 XCB_EXTENSION(XTest, "yes")
 192 XCB_EXTENSION(Xv, "yes")
 193 XCB_EXTENSION(XvMC, "yes")
 194
 195 AC_ARG_WITH(launchd, AS_HELP_STRING([--with-launchd], [Build with support for Apple's launchd (default: auto)]), [LAUNCHD=$withval], [LAUNCHD=auto])
 196 if test "x$LAUNCHD" = xauto; then
 197         unset LAUNCHD
 198         AC_CHECK_PROG(LAUNCHD, [launchd], [yes], [no], [$PATH$PATH_SEPARATOR/sbin])
 199 fi
 200
 201 if test "x$LAUNCHD" = xyes ; then
 202         AC_DEFINE(HAVE_LAUNCHD, 1, [launchd support available])
 203 fi
 204
 205 AC_CONFIG_FILES([
 206 Makefile
 207 doc/Makefile
 208 src/Makefile
 209 tests/Makefile
 210 ])
 211
 212 AC_CONFIG_FILES([
 213 xcb.pc
 214 xcb-composite.pc
 215 xcb-damage.pc
 216 xcb-dpms.pc
 217 xcb-dri2.pc
 218 xcb-glx.pc
 219 xcb-randr.pc
 220 xcb-record.pc
 221 xcb-render.pc
 222 xcb-res.pc
 223 xcb-screensaver.pc
 224 xcb-shape.pc
 225 xcb-shm.pc
 226 xcb-sync.pc
 227 xcb-xevie.pc
 228 xcb-xf86dri.pc
 229 xcb-xfixes.pc
 230 xcb-xinerama.pc
 231 xcb-xinput.pc
 232 xcb-xkb.pc
 233 xcb-xprint.pc
 234 xcb-xselinux.pc
 235 xcb-xtest.pc
 236 xcb-xv.pc
 237 xcb-xvmc.pc
 238 ])
 239
 240 AC_CONFIG_FILES([
 241 doc/xcb.doxygen
 242 ])
 243
 244 AC_OUTPUT
 245
 246 dnl Configuration output
 247
 248 echo ""
 249 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 250 echo ""
 251 echo "  Configuration"
 252 echo "    XDM support.........: ${have_xdmcp}"
 253 echo "    Build unit tests....: ${HAVE_CHECK}"
 254 echo "      with html results.: ${HTML_CHECK_RESULT}"
 255 echo "    XCB buffer size.....: ${xcb_queue_buffer_size}"
 256 echo ""
 257 echo "  X11 extensions"
 258 echo "    Composite...........: ${BUILD_COMPOSITE}"
 259 echo "    Damage..............: ${BUILD_DAMAGE}"
 260 echo "    Dpms................: ${BUILD_DPMS}"
 261 echo "    Dri2................: ${BUILD_DRI2}"
 262 echo "    Glx.................: ${BUILD_GLX}"
 263 echo "    Randr...............: ${BUILD_RANDR}"
 264 echo "    Record..............: ${BUILD_RECORD}"
 265 echo "    Render..............: ${BUILD_RENDER}"
 266 echo "    Resource............: ${BUILD_RESOURCE}"
 267 echo "    Screensaver.........: ${BUILD_SCREENSAVER}"
 268 echo "    selinux.............: ${BUILD_SELINUX}"
 269 echo "    Shape...............: ${BUILD_SHAPE}"
 270 echo "    Shm.................: ${BUILD_SHM}"
 271 echo "    Sync................: ${BUILD_SYNC}"
 272 echo "    Xevie...............: ${BUILD_XEVIE}"
 273 echo "    Xfixes..............: ${BUILD_XFIXES}"
 274 echo "    Xfree86-dri.........: ${BUILD_XFREE86_DRI}"
 275 echo "    xinerama............: ${BUILD_XINERAMA}"
 276 echo "    xinput..............: ${BUILD_XINPUT}"
 277 echo "    xkb.................: ${BUILD_XKB}"
 278 echo "    xprint..............: ${BUILD_XPRINT}"
 279 echo "    xtest...............: ${BUILD_XTEST}"
 280 echo "    xv..................: ${BUILD_XV}"
 281 echo "    xvmc................: ${BUILD_XVMC}"
 282 echo ""
 283 echo "  Used CFLAGS:"
 284 echo "    CPPFLAGS............: ${CPPFLAGS}"
 285 echo "    CFLAGS..............: ${CFLAGS}"
 286 echo "    Warning CFLAGS......: ${CWARNFLAGS}"
 287 echo ""
 288 echo "  Installation:"
 289 echo "    Prefix..............: ${prefix}"
 290 echo ""