git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.57)
   5 AC_INIT([libxcb],
   6         1.6,
   7         [xcb@lists.freedesktop.org])
   8 AC_CONFIG_SRCDIR([xcb.pc.in])
   9 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  10
  11 AM_PATH_PYTHON([2.5])
  12
  13 PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
  14 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
  15
  16 AC_CONFIG_HEADERS([src/config.h])
  17
  18 AC_PROG_LIBTOOL
  19 AC_PROG_CC
  20
  21 AC_PATH_PROG(XSLTPROC, xsltproc, no)
  22 if test "$XSLTPROC" = "no"; then
  23    AC_MSG_ERROR([XCB requires xsltproc.])
  24 fi
  25
  26 HTML_CHECK_RESULT=false
  27 if test x"$HAVE_CHECK" = xyes; then
  28         if test x"$XSLTPROC" != xno; then
  29                 HTML_CHECK_RESULT=true
  30         fi
  31 fi
  32 AC_SUBST(HTML_CHECK_RESULT)
  33
  34 # Checks for pkg-config packages
  35 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.6)
  36 NEEDED="pthread-stubs xau >= 0.99.2"
  37 PKG_CHECK_MODULES(NEEDED, $NEEDED)
  38
  39 have_xdmcp="no"
  40 PKG_CHECK_MODULES(XDMCP, xdmcp,
  41         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  42                 [
  43                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  44                 NEEDED="$NEEDED xdmcp"
  45                 have_xdmcp="yes"
  46                 ],
  47                 [
  48                 XDMCP_CFLAGS=
  49                 XDMCP_LIBS=
  50                 ], [$XDMCP_LIBS]),
  51         [AC_MSG_RESULT(no)])
  52
  53 AC_SUBST(NEEDED)
  54
  55 # Find the xcb-proto protocol descriptions
  56 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  57 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  58 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  59 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  60
  61 # Find the xcb-proto version
  62 XCBPROTO_VERSION=`$PKG_CONFIG --modversion xcb-proto`
  63 AC_SUBST(XCBPROTO_VERSION)
  64
  65 # Find the xcbgen Python package
  66 AC_MSG_CHECKING(XCBPROTO_XCBPYTHONDIR)
  67 XCBPROTO_XCBPYTHONDIR=`$PKG_CONFIG --variable=pythondir xcb-proto`
  68 AC_MSG_RESULT($XCBPROTO_XCBPYTHONDIR)
  69 AC_SUBST(XCBPROTO_XCBPYTHONDIR)
  70
  71 AC_HEADER_STDC
  72 AC_SEARCH_LIBS(getaddrinfo, socket)
  73 AC_SEARCH_LIBS(connect, socket)
  74
  75 case $host_os in
  76 linux*)
  77         AC_DEFINE([HAVE_ABSTRACT_SOCKETS], 1, [Define if your platform supports abstract sockets])
  78         ;;
  79 esac
  80
  81 dnl define buffer queue size
  82 AC_ARG_WITH([queue-size],
  83             AC_HELP_STRING([--with-queue-size=SIZE],
  84             [Set the XCB buffer queue size (default is 16384)]),
  85             [xcb_queue_buffer_size="$withval"],
  86             [xcb_queue_buffer_size=16384])
  87 AC_DEFINE_UNQUOTED(XCB_QUEUE_BUFFER_SIZE, [$xcb_queue_buffer_size],
  88                    [XCB buffer queue size])
  89
  90 dnl check for the sockaddr_un.sun_len member
  91 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
  92                 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN,1,[Have the sockaddr_un.sun_len member.])],
  93                 [],
  94                 [ #include <sys/types.h>
  95                   #include <sys/un.h>
  96                 ])
  97
  98 xcbincludedir='${includedir}/xcb'
  99 AC_SUBST(xcbincludedir)
 100
 101 if  test "x$GCC" = xyes ; then
 102     CWARNFLAGS="-Wall -pedantic -Wpointer-arith \
 103                 -Wstrict-prototypes -Wmissing-declarations -Wnested-externs"
 104 else
 105     AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
 106     if test "x$SUNCC" = "xyes"; then
 107         CWARNFLAGS="-v"
 108     fi
 109 fi
 110 AC_SUBST(CWARNFLAGS)
 111
 112 XCB_CHECK_VISIBILITY()
 113
 114 # htmldir is not defined prior to autoconf 2.59c, so on earlier versions
 115 # set an equivalent value.
 116 AC_PREREQ([2.59c], [], [AC_SUBST([htmldir], [m4_ifset([AC_PACKAGE_TARNAME],
 117           ['${datadir}/doc/${PACKAGE_TARNAME}'],
 118           ['${datadir}/doc/${PACKAGE}'])
 119 ])])
 120
 121 XCB_CHECK_DOXYGEN()
 122
 123 case $host_os in
 124         # darwin has poll() but can't be used to poll character devices (atleast through SnowLeopard)
 125         darwin*) ;;
 126         *)
 127                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 128         ;;
 129 esac
 130
 131 XCB_EXTENSION(Composite, "yes")
 132 XCB_EXTENSION(Damage, "yes")
 133 XCB_EXTENSION(DPMS, "yes")
 134 XCB_EXTENSION(DRI2, "yes")
 135 XCB_EXTENSION(GLX, "yes")
 136 XCB_EXTENSION(RandR, "yes")
 137 XCB_EXTENSION(Record, "yes")
 138 XCB_EXTENSION(Render, "yes")
 139 XCB_EXTENSION(Resource, "yes")
 140 XCB_EXTENSION(Screensaver, "yes")
 141 XCB_EXTENSION(Shape, "yes")
 142 XCB_EXTENSION(Shm, "yes")
 143 XCB_EXTENSION(Sync, "yes")
 144 XCB_EXTENSION(Xevie, "yes")
 145 XCB_EXTENSION(XFixes, "yes")
 146 XCB_EXTENSION(XFree86-DRI, "yes")
 147 XCB_EXTENSION(Xinerama, "yes")
 148 XCB_EXTENSION(XInput, "no")
 149 XCB_EXTENSION(XKB, "no")
 150 XCB_EXTENSION(Xprint, "yes")
 151 XCB_EXTENSION(SELinux, "no")
 152 XCB_EXTENSION(XTest, "yes")
 153 XCB_EXTENSION(Xv, "yes")
 154 XCB_EXTENSION(XvMC, "yes")
 155
 156 AC_ARG_WITH(launchd, AS_HELP_STRING([--with-launchd], [Build with support for Apple's launchd (default: auto)]), [LAUNCHD=$withval], [LAUNCHD=auto])
 157 if test "x$LAUNCHD" = xauto; then
 158         unset LAUNCHD
 159         AC_CHECK_PROG(LAUNCHD, [launchd], [yes], [no])
 160 fi
 161
 162 if test "x$LAUNCHD" = xyes ; then
 163         AC_DEFINE(HAVE_LAUNCHD, 1, [launchd support available])
 164 fi
 165
 166 AC_CONFIG_FILES([
 167 Makefile
 168 doc/Makefile
 169 src/Makefile
 170 tests/Makefile
 171 ])
 172
 173 AC_CONFIG_FILES([
 174 xcb.pc
 175 xcb-composite.pc
 176 xcb-damage.pc
 177 xcb-dpms.pc
 178 xcb-dri2.pc
 179 xcb-glx.pc
 180 xcb-randr.pc
 181 xcb-record.pc
 182 xcb-render.pc
 183 xcb-res.pc
 184 xcb-screensaver.pc
 185 xcb-shape.pc
 186 xcb-shm.pc
 187 xcb-sync.pc
 188 xcb-xevie.pc
 189 xcb-xf86dri.pc
 190 xcb-xfixes.pc
 191 xcb-xinerama.pc
 192 xcb-xinput.pc
 193 xcb-xkb.pc
 194 xcb-xprint.pc
 195 xcb-xselinux.pc
 196 xcb-xtest.pc
 197 xcb-xv.pc
 198 xcb-xvmc.pc
 199 ])
 200
 201 AC_CONFIG_FILES([
 202 doc/xcb.doxygen
 203 ])
 204
 205 AC_OUTPUT
 206
 207 dnl Configuration output
 208
 209 echo ""
 210 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 211 echo ""
 212 echo "  Configuration"
 213 echo "    XDM support.........: ${have_xdmcp}"
 214 echo "    Build unit tests....: ${HAVE_CHECK}"
 215 echo "    XCB buffer size.....: ${xcb_queue_buffer_size}"
 216 echo ""
 217 echo "  Used CFLAGS:"
 218 echo "    CPPFLAGS............: ${CPPFLAGS}"
 219 echo "    CFLAGS..............: ${CFLAGS}"
 220 echo "    Warning CFLAGS......: ${CWARNFLAGS}"
 221 echo ""
 222 echo "  Installation:"
 223 echo "    Prefix..............: ${prefix}"
 224 echo ""