git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Initialize Autoconf
   5 AC_PREREQ([2.60])
   6 AC_INIT([libxcb],
   7         1.9,
   8         [xcb@lists.freedesktop.org])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AC_CONFIG_SRCDIR([xcb.pc.in])
  12
  13 # Initialize Automake
  14 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 # Set common system defines for POSIX extensions, such as _GNU_SOURCE
  18 # Must be called before any macros that run the compiler (like AC_PROG_LIBTOOL)
  19 # to avoid autoconf errors.
  20 AC_USE_SYSTEM_EXTENSIONS
  21
  22 AM_PATH_PYTHON([2.6])
  23
  24 PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
  25 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
  26
  27 AC_CONFIG_HEADERS([src/config.h])
  28
  29 AC_LIBTOOL_WIN32_DLL
  30 AC_PROG_LIBTOOL
  31 AC_PROG_CC
  32
  33 XSLTPROC=no
  34 HTML_CHECK_RESULT=no
  35 if test x"$HAVE_CHECK" = xyes; then
  36         AC_PATH_PROG(XSLTPROC, xsltproc, no)
  37         if test x"$XSLTPROC" != xno; then
  38                 HTML_CHECK_RESULT=yes
  39         fi
  40 fi
  41 AC_SUBST(HTML_CHECK_RESULT)
  42
  43 # Checks for pkg-config packages
  44 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.9)
  45 NEEDED="pthread-stubs xau >= 0.99.2"
  46 PKG_CHECK_MODULES(NEEDED, $NEEDED)
  47
  48 have_xdmcp="no"
  49 PKG_CHECK_MODULES(XDMCP, xdmcp,
  50         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  51                 [
  52                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  53                 NEEDED="$NEEDED xdmcp"
  54                 have_xdmcp="yes"
  55                 ],
  56                 [
  57                 XDMCP_CFLAGS=
  58                 XDMCP_LIBS=
  59                 ], [$XDMCP_LIBS]),
  60         [AC_MSG_RESULT(no)])
  61
  62 AC_SUBST(NEEDED)
  63
  64 # Find the xcb-proto protocol descriptions
  65 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  66 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  67 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  68 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  69
  70 # Find the xcb-proto version
  71 XCBPROTO_VERSION=`$PKG_CONFIG --modversion xcb-proto`
  72 AC_SUBST(XCBPROTO_VERSION)
  73
  74 # Find the xcbgen Python package
  75 AC_MSG_CHECKING(XCBPROTO_XCBPYTHONDIR)
  76 XCBPROTO_XCBPYTHONDIR=`$PKG_CONFIG --variable=pythondir xcb-proto`
  77 AC_MSG_RESULT($XCBPROTO_XCBPYTHONDIR)
  78 AC_SUBST(XCBPROTO_XCBPYTHONDIR)
  79
  80 AC_HEADER_STDC
  81 AC_SEARCH_LIBS(getaddrinfo, socket)
  82 AC_SEARCH_LIBS(connect, socket)
  83
  84 have_sendmsg="no"
  85 case $host_os in
  86 linux*)
  87         AC_SEARCH_LIBS(sendmsg, socket, [have_sendmsg="yes"], [have_sendmsg="no"])
  88         ;;
  89 esac
  90
  91 case x$have_sendmsg in
  92 xyes)
  93         AC_DEFINE([HAVE_SENDMSG],1,[Define if your platform supports sendmsg])
  94         ;;
  95 esac
  96
  97 have_win32="no"
  98 lt_enable_auto_import=""
  99 case $host_os in
 100 mingw*)
 101         have_win32="yes"
 102         lt_enable_auto_import="-Wl,--enable-auto-import"
 103         ;;
 104 linux*)
 105         AC_DEFINE([HAVE_ABSTRACT_SOCKETS], 1, [Define if your platform supports abstract sockets])
 106         ;;
 107 esac
 108
 109 AC_SUBST(lt_enable_auto_import)
 110 AM_CONDITIONAL([XCB_HAVE_WIN32], [test "x${have_win32}" = "xyes"])
 111
 112 dnl define buffer queue size
 113 AC_ARG_WITH([queue-size],
 114             AC_HELP_STRING([--with-queue-size=SIZE],
 115             [Set the XCB buffer queue size (default is 16384)]),
 116             [xcb_queue_buffer_size="$withval"],
 117             [xcb_queue_buffer_size=16384])
 118 AC_DEFINE_UNQUOTED(XCB_QUEUE_BUFFER_SIZE, [$xcb_queue_buffer_size],
 119                    [XCB buffer queue size])
 120
 121 dnl check for the sockaddr_un.sun_len member
 122 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 123                 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN,1,[Have the sockaddr_un.sun_len member.])],
 124                 [],
 125                 [ #include <sys/types.h>
 126                   #include <sys/un.h>
 127                 ])
 128
 129 dnl check for support for Solaris Trusted Extensions
 130 AC_CHECK_HEADERS([tsol/label.h])
 131 AC_CHECK_FUNCS([is_system_labeled])
 132
 133 dnl check for IOV_MAX, and fall back to UIO_MAXIOV on BSDish systems
 134 AC_CHECK_DECL([IOV_MAX], [],
 135               [AC_CHECK_DECL([UIO_MAXIOV], [AC_DEFINE([IOV_MAX], [UIO_MAXIOV])],
 136                                            [AC_DEFINE([IOV_MAX], [16], [Define if not provided by <limits.h>])],
 137                                            [[#include <sys/uio.h>]])],
 138               [[#include <limits.h>]])
 139
 140 xcbincludedir='${includedir}/xcb'
 141 AC_SUBST(xcbincludedir)
 142
 143 if  test "x$GCC" = xyes ; then
 144     CWARNFLAGS="-Wall -Wpointer-arith -Wold-style-definition \
 145                 -Wstrict-prototypes -Wmissing-declarations -Wnested-externs"
 146 else
 147     AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
 148     if test "x$SUNCC" = "xyes"; then
 149         CWARNFLAGS="-v -fd"
 150     fi
 151 fi
 152 AC_SUBST(CWARNFLAGS)
 153
 154 XCB_CHECK_VISIBILITY()
 155
 156 XCB_CHECK_DOXYGEN()
 157
 158 AC_CHECK_FUNC(getaddrinfo, [AC_DEFINE(HAVE_GETADDRINFO, 1, [getaddrinfo() function is available])], )
 159
 160 case $host_os in
 161         # darwin through Snow Leopard has poll() but can't be used to poll character devices.
 162         darwin@<:@789@:>@*|darwin10*) ;;
 163         darwin*)
 164                 _ac_xorg_macosx_version_min=""
 165                 if echo $CPPFLAGS $CFLAGS | grep -q mmacosx-version-min ; then
 166                         _ac_xorg_macosx_version_min=`echo $CPPFLAGS $CFLAGS | sed 's/^.*-mmacosx-version-min=\(@<:@^ @:>@*\).*$/\1/'`
 167                 else
 168                         _ac_xorg_macosx_version_min=$MACOSX_DEPLOYMENT_TARGET
 169                 fi
 170                 case $_ac_xorg_macosx_version_min in
 171                         10.@<:@0123456@:>@|10.@<:@0123456@:>@.*) ;;
 172                         *)
 173                                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 174                         ;;
 175                 esac
 176                 unset _ac_xorg_macosx_version_min
 177                 ;;
 178         *)
 179                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 180         ;;
 181 esac
 182
 183 XCB_EXTENSION(Composite, "yes")
 184 XCB_EXTENSION(Damage, "yes")
 185 XCB_EXTENSION(DPMS, "yes")
 186 XCB_EXTENSION(DRI2, "yes")
 187 XCB_EXTENSION(DRI3, "$have_sendmsg")
 188 XCB_EXTENSION(GLX, "yes")
 189 XCB_EXTENSION(RandR, "yes")
 190 XCB_EXTENSION(Record, "yes")
 191 XCB_EXTENSION(Render, "yes")
 192 XCB_EXTENSION(Resource, "yes")
 193 XCB_EXTENSION(Screensaver, "yes")
 194 XCB_EXTENSION(Shape, "yes")
 195 XCB_EXTENSION(Shm, "yes")
 196 XCB_EXTENSION(Sync, "yes")
 197 XCB_EXTENSION(Xevie, "yes")
 198 XCB_EXTENSION(XFixes, "yes")
 199 XCB_EXTENSION(XFree86-DRI, "yes")
 200 XCB_EXTENSION(Xinerama, "yes")
 201 XCB_EXTENSION(XInput, "no")
 202 XCB_EXTENSION(XKB, "yes")
 203 XCB_EXTENSION(Xprint, "yes")
 204 XCB_EXTENSION(SELinux, "no")
 205 XCB_EXTENSION(XTest, "yes")
 206 XCB_EXTENSION(Xv, "yes")
 207 XCB_EXTENSION(XvMC, "yes")
 208
 209 AC_ARG_WITH(launchd, AS_HELP_STRING([--with-launchd], [Build with support for Apple's launchd (default: auto)]), [LAUNCHD=$withval], [LAUNCHD=auto])
 210 if test "x$LAUNCHD" = xauto; then
 211         unset LAUNCHD
 212         AC_CHECK_PROG(LAUNCHD, [launchd], [yes], [no], [$PATH$PATH_SEPARATOR/sbin])
 213 fi
 214
 215 if test "x$LAUNCHD" = xyes ; then
 216         AC_DEFINE(HAVE_LAUNCHD, 1, [launchd support available])
 217 fi
 218
 219 AC_CONFIG_FILES([
 220 Makefile
 221 doc/Makefile
 222 src/Makefile
 223 tests/Makefile
 224 ])
 225
 226 AC_CONFIG_FILES([
 227 xcb.pc
 228 xcb-composite.pc
 229 xcb-damage.pc
 230 xcb-dpms.pc
 231 xcb-dri2.pc
 232 xcb-dri3.pc
 233 xcb-glx.pc
 234 xcb-randr.pc
 235 xcb-record.pc
 236 xcb-render.pc
 237 xcb-res.pc
 238 xcb-screensaver.pc
 239 xcb-shape.pc
 240 xcb-shm.pc
 241 xcb-sync.pc
 242 xcb-xevie.pc
 243 xcb-xf86dri.pc
 244 xcb-xfixes.pc
 245 xcb-xinerama.pc
 246 xcb-xinput.pc
 247 xcb-xkb.pc
 248 xcb-xprint.pc
 249 xcb-xselinux.pc
 250 xcb-xtest.pc
 251 xcb-xv.pc
 252 xcb-xvmc.pc
 253 ])
 254
 255 AC_CONFIG_FILES([
 256 doc/xcb.doxygen
 257 ])
 258
 259 AC_OUTPUT
 260
 261 dnl Configuration output
 262
 263 echo ""
 264 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 265 echo ""
 266 echo "  Configuration"
 267 echo "    XDM support.........: ${have_xdmcp}"
 268 echo "    sendmsg fd passing..: ${have_sendmsg}"
 269 echo "    Build unit tests....: ${HAVE_CHECK}"
 270 echo "      with html results.: ${HTML_CHECK_RESULT}"
 271 echo "    XCB buffer size.....: ${xcb_queue_buffer_size}"
 272 echo ""
 273 echo "  X11 extensions"
 274 echo "    Composite...........: ${BUILD_COMPOSITE}"
 275 echo "    Damage..............: ${BUILD_DAMAGE}"
 276 echo "    Dpms................: ${BUILD_DPMS}"
 277 echo "    Dri2................: ${BUILD_DRI2}"
 278 echo "    Dri3................: ${BUILD_DRI3}"
 279 echo "    Glx.................: ${BUILD_GLX}"
 280 echo "    Randr...............: ${BUILD_RANDR}"
 281 echo "    Record..............: ${BUILD_RECORD}"
 282 echo "    Render..............: ${BUILD_RENDER}"
 283 echo "    Resource............: ${BUILD_RESOURCE}"
 284 echo "    Screensaver.........: ${BUILD_SCREENSAVER}"
 285 echo "    selinux.............: ${BUILD_SELINUX}"
 286 echo "    Shape...............: ${BUILD_SHAPE}"
 287 echo "    Shm.................: ${BUILD_SHM}"
 288 echo "    Sync................: ${BUILD_SYNC}"
 289 echo "    Xevie...............: ${BUILD_XEVIE}"
 290 echo "    Xfixes..............: ${BUILD_XFIXES}"
 291 echo "    Xfree86-dri.........: ${BUILD_XFREE86_DRI}"
 292 echo "    xinerama............: ${BUILD_XINERAMA}"
 293 echo "    xinput..............: ${BUILD_XINPUT}"
 294 echo "    xkb.................: ${BUILD_XKB}"
 295 echo "    xprint..............: ${BUILD_XPRINT}"
 296 echo "    xtest...............: ${BUILD_XTEST}"
 297 echo "    xv..................: ${BUILD_XV}"
 298 echo "    xvmc................: ${BUILD_XVMC}"
 299 echo ""
 300 echo "  Used CFLAGS:"
 301 echo "    CPPFLAGS............: ${CPPFLAGS}"
 302 echo "    CFLAGS..............: ${CFLAGS}"
 303 echo "    Warning CFLAGS......: ${CWARNFLAGS}"
 304 echo ""
 305 echo "  Installation:"
 306 echo "    Prefix..............: ${prefix}"
 307 echo ""