git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.57)
   5 AC_INIT([libxcb],
   6         1.0,
   7         [xcb@lists.freedesktop.org])
   8 AC_CONFIG_SRCDIR([xcb.pc.in])
   9 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  10
  11 PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
  12 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
  13
  14 AC_CONFIG_HEADERS([src/config.h])
  15
  16 AC_PROG_LIBTOOL
  17 AC_PROG_CC
  18
  19 AC_PATH_PROG(XSLTPROC, xsltproc, no)
  20 if test "$XSLTPROC" = "no"; then
  21    AC_MSG_ERROR([XCB requires xsltproc.])
  22 fi
  23
  24 HTML_CHECK_RESULT=false
  25 if test x"$HAVE_CHECK" = xyes; then
  26         if test x"$XSLTPROC" != xno; then
  27                 HTML_CHECK_RESULT=true
  28         fi
  29 fi
  30 AC_SUBST(HTML_CHECK_RESULT)
  31
  32 # Checks for pkg-config packages
  33 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.0)
  34 NEEDED="pthread-stubs xau >= 0.99.2"
  35 PKG_CHECK_MODULES(NEEDED, $NEEDED)
  36
  37 have_xdmcp="no"
  38 PKG_CHECK_MODULES(XDMCP, xdmcp,
  39         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  40                 [
  41                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  42                 NEEDED="$NEEDED xdmcp"
  43                 have_xdmcp="yes"
  44                 ],
  45                 [
  46                 XDMCP_CFLAGS=
  47                 XDMCP_LIBS=
  48                 ], [$XDMCP_LIBS]),
  49         [AC_MSG_RESULT(no)])
  50
  51 AC_CHECK_HEADER([execinfo.h], [AC_DEFINE(HAVE_BACKTRACE,1,[Has backtrace*() needed for retrieving stack traces])])
  52
  53 AC_SUBST(NEEDED)
  54
  55 # Find the xcb-proto protocol descriptions
  56 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  57 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  58 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  59 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  60
  61 AC_HEADER_STDC
  62 AC_SEARCH_LIBS(getaddrinfo, socket)
  63 AC_SEARCH_LIBS(connect, socket)
  64
  65 xcbincludedir='${includedir}/xcb'
  66 AC_SUBST(xcbincludedir)
  67
  68 if  test "x$GCC" = xyes ; then
  69     CWARNFLAGS="-Wall -pedantic -Wpointer-arith \
  70                 -Wstrict-prototypes -Wmissing-declarations -Wnested-externs"
  71 else
  72     AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  73     if test "x$SUNCC" = "xyes"; then
  74         CWARNFLAGS="-v"
  75     fi
  76 fi
  77 AC_SUBST(CWARNFLAGS)
  78
  79 GCC_CHECK_VISIBILITY()
  80
  81 # htmldir is not defined prior to autoconf 2.59c, so on earlier versions
  82 # set an equivalent value.
  83 AC_PREREQ([2.59c], [], [AC_SUBST([htmldir], [m4_ifset([AC_PACKAGE_TARNAME],
  84           ['${datadir}/doc/${PACKAGE_TARNAME}'],
  85           ['${datadir}/doc/${PACKAGE}'])
  86 ])])
  87 AM_CHECK_DOXYGEN()
  88
  89 AC_CONFIG_FILES([Makefile src/Makefile tests/Makefile doc/Makefile])
  90 AC_CONFIG_FILES([xcb.pc xcb-xlib.pc xcb-composite.pc xcb-damage.pc xcb-dpms.pc xcb-glx.pc xcb-randr.pc xcb-record.pc xcb-render.pc xcb-res.pc xcb-screensaver.pc xcb-shape.pc xcb-shm.pc xcb-sync.pc xcb-xevie.pc xcb-xf86dri.pc xcb-xfixes.pc xcb-xinerama.pc xcb-xprint.pc xcb-xtest.pc xcb-xv.pc xcb-xvmc.pc])
  91 AC_CONFIG_FILES([doc/xcb.doxygen])
  92
  93 AC_OUTPUT
  94
  95 dnl Configuration output
  96
  97 echo ""
  98 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
  99 echo ""
 100 echo "  Configuration"
 101 echo "    XDM support.........: ${have_xdmcp}"
 102 echo "    Build unit tests....: ${HAVE_CHECK}"
 103 echo ""
 104 echo "  Used CFLAGS:"
 105 echo "    CPPFLAGS............: ${CPPFLAGS}"
 106 echo "    CFLAGS..............: ${CFLAGS}"
 107 echo "    Warning CFLAGS......: ${CWARNFLAGS}"
 108 echo ""
 109 echo "  Installation:"
 110 echo "    Prefix..............: ${prefix}"
 111 echo ""