git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 # Initialize Autoconf
   4 AC_PREREQ([2.60])
   5 AC_INIT([libxcb],[1.10],
   6         [https://bugs.freedesktop.org/enter_bug.cgi?product=xcb],
   7         [libxcb])
   8 AC_CONFIG_AUX_DIR([build-aux])
   9 AC_CONFIG_MACRO_DIR([m4])
  10 AC_CONFIG_SRCDIR([xcb.pc.in])
  11 AC_CONFIG_HEADERS([src/config.h])
  12
  13 # Initialize Automake
  14 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  15 AM_PATH_PYTHON([2.6])
  16
  17 # Set common system defines for POSIX extensions, such as _GNU_SOURCE
  18 # Must be called before any macros that run the compiler (like AC_PROG_LIBTOOL)
  19 # to avoid autoconf errors.
  20 AC_USE_SYSTEM_EXTENSIONS
  21
  22 # Initialize libtool
  23 AC_LIBTOOL_WIN32_DLL
  24 AC_PROG_LIBTOOL
  25
  26 # Require xorg-macros minimum of 1.18 - Initial version
  27 m4_ifndef([XORG_MACROS_VERSION],
  28           [m4_fatal([must install xorg-macros 1.18 or later before running autoconf/autogen])])
  29 XORG_MACROS_VERSION(1.18)
  30 XORG_DEFAULT_OPTIONS
  31
  32 PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
  33 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
  34
  35 XSLTPROC=no
  36 HTML_CHECK_RESULT=no
  37 if test x"$HAVE_CHECK" = xyes; then
  38         AC_PATH_PROG(XSLTPROC, xsltproc, no)
  39         if test x"$XSLTPROC" != xno; then
  40                 HTML_CHECK_RESULT=yes
  41         fi
  42 fi
  43 AC_SUBST(HTML_CHECK_RESULT)
  44
  45 # Checks for pkg-config packages
  46 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.10)
  47 NEEDED="pthread-stubs xau >= 0.99.2"
  48 PKG_CHECK_MODULES(NEEDED, $NEEDED)
  49
  50 have_xdmcp="no"
  51 PKG_CHECK_MODULES(XDMCP, xdmcp,
  52         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  53                 [
  54                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  55                 NEEDED="$NEEDED xdmcp"
  56                 have_xdmcp="yes"
  57                 ],
  58                 [
  59                 XDMCP_CFLAGS=
  60                 XDMCP_LIBS=
  61                 ], [$XDMCP_LIBS]),
  62         [AC_MSG_RESULT(no)])
  63
  64 AC_SUBST(NEEDED)
  65
  66 # Find the xcb-proto protocol descriptions
  67 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  68 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  69 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  70 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  71
  72 # Find the xcb-proto version
  73 XCBPROTO_VERSION=`$PKG_CONFIG --modversion xcb-proto`
  74 AC_SUBST(XCBPROTO_VERSION)
  75
  76 # Find the xcbgen Python package
  77 AC_MSG_CHECKING(XCBPROTO_XCBPYTHONDIR)
  78 XCBPROTO_XCBPYTHONDIR=`$PKG_CONFIG --variable=pythondir xcb-proto`
  79 AC_MSG_RESULT($XCBPROTO_XCBPYTHONDIR)
  80 AC_SUBST(XCBPROTO_XCBPYTHONDIR)
  81
  82 AC_HEADER_STDC
  83 AC_SEARCH_LIBS(getaddrinfo, socket)
  84 AC_SEARCH_LIBS(connect, socket)
  85
  86 AC_ARG_ENABLE(sendfds, AS_HELP_STRING([--disable-sendfds], [Support FD passing (default: auto)]),
  87               [sendfds=$enableval], [sendfds=auto])
  88
  89 case x$sendfds in
  90 xauto)
  91         AC_SEARCH_LIBS(sendmsg, socket, [sendfds="yes"], [sendfds="no"])
  92         ;;
  93 esac
  94
  95 # XPG4v2/UNIX95 added msg_control - check to see if we need to define
  96 # _XOPEN_SOURCE to get it (such as on Solaris)
  97 AC_CHECK_MEMBER([struct msghdr.msg_control], [], [],
  98                  [
  99 AC_INCLUDES_DEFAULT
 100 #include <sys/socket.h>
 101                  ])
 102 # First try for Solaris in C99 compliant mode, which requires XPG6/UNIX03
 103 if test "x$ac_cv_member_struct_msghdr_msg_control" = xno; then
 104     unset ac_cv_member_struct_msghdr_msg_control
 105     AC_MSG_NOTICE([trying again with _XOPEN_SOURCE=600])
 106     AC_CHECK_MEMBER([struct msghdr.msg_control],
 107                     [AC_DEFINE([_XOPEN_SOURCE], [600],
 108                        [Defined if needed to expose struct msghdr.msg_control])
 109                     ], [], [
 110 #define _XOPEN_SOURCE 600
 111 AC_INCLUDES_DEFAULT
 112 #include <sys/socket.h>
 113                      ])
 114 fi
 115 # If that didn't work, fall back to XPG5/UNIX98 with C89
 116 if test "x$ac_cv_member_struct_msghdr_msg_control" = xno; then
 117     unset ac_cv_member_struct_msghdr_msg_control
 118     AC_MSG_NOTICE([trying again with _XOPEN_SOURCE=500])
 119     AC_CHECK_MEMBER([struct msghdr.msg_control],
 120                     [AC_DEFINE([_XOPEN_SOURCE], [500],
 121                        [Defined if needed to expose struct msghdr.msg_control])
 122                     ], [sendfds="no"], [
 123 #define _XOPEN_SOURCE 500
 124 AC_INCLUDES_DEFAULT
 125 #include <sys/socket.h>
 126                      ])
 127 fi
 128
 129 case x$sendfds in
 130 xyes)
 131         AC_DEFINE([HAVE_SENDMSG],1,[Define if your platform supports sendmsg])
 132         ;;
 133 esac
 134
 135 have_win32="no"
 136 lt_enable_auto_import=""
 137 case $host_os in
 138 mingw*)
 139         have_win32="yes"
 140         lt_enable_auto_import="-Wl,--enable-auto-import"
 141         ;;
 142 linux*)
 143         AC_DEFINE([HAVE_ABSTRACT_SOCKETS], 1, [Define if your platform supports abstract sockets])
 144         ;;
 145 esac
 146
 147 AC_SUBST(lt_enable_auto_import)
 148 AM_CONDITIONAL([XCB_HAVE_WIN32], [test "x${have_win32}" = "xyes"])
 149
 150 dnl define buffer queue size
 151 AC_ARG_WITH([queue-size],
 152             AC_HELP_STRING([--with-queue-size=SIZE],
 153             [Set the XCB buffer queue size (default is 16384)]),
 154             [xcb_queue_buffer_size="$withval"],
 155             [xcb_queue_buffer_size=16384])
 156 AC_DEFINE_UNQUOTED(XCB_QUEUE_BUFFER_SIZE, [$xcb_queue_buffer_size],
 157                    [XCB buffer queue size])
 158
 159 dnl check for the sockaddr_un.sun_len member
 160 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 161                 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN,1,[Have the sockaddr_un.sun_len member.])],
 162                 [],
 163                 [ #include <sys/types.h>
 164                   #include <sys/un.h>
 165                 ])
 166
 167 dnl check for support for Solaris Trusted Extensions
 168 AC_CHECK_HEADERS([tsol/label.h])
 169 AC_CHECK_FUNCS([is_system_labeled])
 170
 171 dnl check for IOV_MAX, and fall back to UIO_MAXIOV on BSDish systems
 172 AC_CHECK_DECL([IOV_MAX], [],
 173               [AC_CHECK_DECL([UIO_MAXIOV], [AC_DEFINE([IOV_MAX], [UIO_MAXIOV])],
 174                                            [AC_DEFINE([IOV_MAX], [16], [Define if not provided by <limits.h>])],
 175                                            [[#include <sys/uio.h>]])],
 176               [[#include <limits.h>]])
 177
 178 xcbincludedir='${includedir}/xcb'
 179 AC_SUBST(xcbincludedir)
 180
 181 XCB_CHECK_VISIBILITY()
 182
 183 XCB_CHECK_DOXYGEN()
 184
 185 AC_CHECK_FUNC(getaddrinfo, [AC_DEFINE(HAVE_GETADDRINFO, 1, [getaddrinfo() function is available])], )
 186
 187 case $host_os in
 188         # darwin through Snow Leopard has poll() but can't be used to poll character devices.
 189         darwin@<:@789@:>@*|darwin10*) ;;
 190         darwin*)
 191                 _ac_xorg_macosx_version_min=""
 192                 if echo $CPPFLAGS $CFLAGS | grep -q mmacosx-version-min ; then
 193                         _ac_xorg_macosx_version_min=`echo $CPPFLAGS $CFLAGS | sed 's/^.*-mmacosx-version-min=\(@<:@^ @:>@*\).*$/\1/'`
 194                 else
 195                         _ac_xorg_macosx_version_min=$MACOSX_DEPLOYMENT_TARGET
 196                 fi
 197                 case $_ac_xorg_macosx_version_min in
 198                         10.@<:@0123456@:>@|10.@<:@0123456@:>@.*) ;;
 199                         *)
 200                                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 201                         ;;
 202                 esac
 203                 unset _ac_xorg_macosx_version_min
 204                 ;;
 205         *)
 206                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 207         ;;
 208 esac
 209
 210 XCB_EXTENSION(Composite, "yes")
 211 XCB_EXTENSION(Damage, "yes")
 212 XCB_EXTENSION(DPMS, "yes")
 213 XCB_EXTENSION(DRI2, "yes")
 214 XCB_EXTENSION(DRI3, "$sendfds")
 215 XCB_EXTENSION(GLX, "yes")
 216 XCB_EXTENSION(Present, "yes")
 217 XCB_EXTENSION(RandR, "yes")
 218 XCB_EXTENSION(Record, "yes")
 219 XCB_EXTENSION(Render, "yes")
 220 XCB_EXTENSION(Resource, "yes")
 221 XCB_EXTENSION(Screensaver, "yes")
 222 XCB_EXTENSION(Shape, "yes")
 223 XCB_EXTENSION(Shm, "yes")
 224 XCB_EXTENSION(Sync, "yes")
 225 XCB_EXTENSION(Xevie, "yes")
 226 XCB_EXTENSION(XFixes, "yes")
 227 XCB_EXTENSION(XFree86-DRI, "yes")
 228 XCB_EXTENSION(Xinerama, "yes")
 229 XCB_EXTENSION(XInput, "no")
 230 XCB_EXTENSION(XKB, "yes")
 231 XCB_EXTENSION(Xprint, "yes")
 232 XCB_EXTENSION(SELinux, "no")
 233 XCB_EXTENSION(XTest, "yes")
 234 XCB_EXTENSION(Xv, "yes")
 235 XCB_EXTENSION(XvMC, "yes")
 236
 237 AC_ARG_WITH(launchd, AS_HELP_STRING([--with-launchd], [Build with support for Apple's launchd (default: auto)]), [LAUNCHD=$withval], [LAUNCHD=auto])
 238 if test "x$LAUNCHD" = xauto; then
 239         unset LAUNCHD
 240         AC_CHECK_PROG(LAUNCHD, [launchd], [yes], [no], [$PATH$PATH_SEPARATOR/sbin])
 241 fi
 242
 243 if test "x$LAUNCHD" = xyes ; then
 244         AC_DEFINE(HAVE_LAUNCHD, 1, [launchd support available])
 245 fi
 246
 247 AC_CONFIG_FILES([
 248 Makefile
 249 doc/Makefile
 250 src/Makefile
 251 tests/Makefile
 252 ])
 253
 254 AC_CONFIG_FILES([
 255 xcb.pc
 256 xcb-composite.pc
 257 xcb-damage.pc
 258 xcb-dpms.pc
 259 xcb-dri2.pc
 260 xcb-dri3.pc
 261 xcb-glx.pc
 262 xcb-present.pc
 263 xcb-randr.pc
 264 xcb-record.pc
 265 xcb-render.pc
 266 xcb-res.pc
 267 xcb-screensaver.pc
 268 xcb-shape.pc
 269 xcb-shm.pc
 270 xcb-sync.pc
 271 xcb-xevie.pc
 272 xcb-xf86dri.pc
 273 xcb-xfixes.pc
 274 xcb-xinerama.pc
 275 xcb-xinput.pc
 276 xcb-xkb.pc
 277 xcb-xprint.pc
 278 xcb-xselinux.pc
 279 xcb-xtest.pc
 280 xcb-xv.pc
 281 xcb-xvmc.pc
 282 ])
 283
 284 AC_CONFIG_FILES([
 285 doc/xcb.doxygen
 286 ])
 287
 288 AC_OUTPUT
 289
 290 dnl Configuration output
 291
 292 echo ""
 293 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 294 echo ""
 295 echo "  Configuration"
 296 echo "    XDM support.........: ${have_xdmcp}"
 297 echo "    sendmsg fd passing..: ${sendfds}"
 298 echo "    Build unit tests....: ${HAVE_CHECK}"
 299 echo "      with html results.: ${HTML_CHECK_RESULT}"
 300 echo "    XCB buffer size.....: ${xcb_queue_buffer_size}"
 301 echo ""
 302 echo "  X11 extensions"
 303 echo "    Composite...........: ${BUILD_COMPOSITE}"
 304 echo "    Damage..............: ${BUILD_DAMAGE}"
 305 echo "    Dpms................: ${BUILD_DPMS}"
 306 echo "    Dri2................: ${BUILD_DRI2}"
 307 echo "    Dri3................: ${BUILD_DRI3}"
 308 echo "    Glx.................: ${BUILD_GLX}"
 309 echo "    Randr...............: ${BUILD_RANDR}"
 310 echo "    Record..............: ${BUILD_RECORD}"
 311 echo "    Render..............: ${BUILD_RENDER}"
 312 echo "    Resource............: ${BUILD_RESOURCE}"
 313 echo "    Screensaver.........: ${BUILD_SCREENSAVER}"
 314 echo "    selinux.............: ${BUILD_SELINUX}"
 315 echo "    Shape...............: ${BUILD_SHAPE}"
 316 echo "    Shm.................: ${BUILD_SHM}"
 317 echo "    Sync................: ${BUILD_SYNC}"
 318 echo "    Xevie...............: ${BUILD_XEVIE}"
 319 echo "    Xfixes..............: ${BUILD_XFIXES}"
 320 echo "    Xfree86-dri.........: ${BUILD_XFREE86_DRI}"
 321 echo "    xinerama............: ${BUILD_XINERAMA}"
 322 echo "    xinput..............: ${BUILD_XINPUT}"
 323 echo "    xkb.................: ${BUILD_XKB}"
 324 echo "    xprint..............: ${BUILD_XPRINT}"
 325 echo "    xtest...............: ${BUILD_XTEST}"
 326 echo "    xv..................: ${BUILD_XV}"
 327 echo "    xvmc................: ${BUILD_XVMC}"
 328 echo ""
 329 echo "  Used CFLAGS:"
 330 echo "    CPPFLAGS............: ${CPPFLAGS}"
 331 echo "    CFLAGS..............: ${CFLAGS}"
 332 echo "    Warning CFLAGS......: ${BASE_CFLAGS}"
 333 echo ""
 334 echo "  Installation:"
 335 echo "    Prefix..............: ${prefix}"
 336 echo ""