git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Initialize Autoconf
   5 AC_PREREQ(2.57)
   6 AC_INIT([libxcb],
   7         1.9,
   8         [xcb@lists.freedesktop.org])
   9 AC_CONFIG_SRCDIR([xcb.pc.in])
  10
  11 # Initialize Automake
  12 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  13 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  14
  15 # Set common system defines for POSIX extensions, such as _GNU_SOURCE
  16 # Must be called before any macros that run the compiler (like AC_PROG_LIBTOOL)
  17 # to avoid autoconf errors.
  18 AC_USE_SYSTEM_EXTENSIONS
  19
  20 AM_PATH_PYTHON([2.6])
  21
  22 PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
  23 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
  24
  25 AC_CONFIG_HEADERS([src/config.h])
  26
  27 AC_LIBTOOL_WIN32_DLL
  28 AC_PROG_LIBTOOL
  29 AC_PROG_CC
  30
  31 XSLTPROC=no
  32 HTML_CHECK_RESULT=no
  33 if test x"$HAVE_CHECK" = xyes; then
  34         AC_PATH_PROG(XSLTPROC, xsltproc, no)
  35         if test x"$XSLTPROC" != xno; then
  36                 HTML_CHECK_RESULT=yes
  37         fi
  38 fi
  39 AC_SUBST(HTML_CHECK_RESULT)
  40
  41 # Checks for pkg-config packages
  42 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.7)
  43 NEEDED="pthread-stubs xau >= 0.99.2"
  44 PKG_CHECK_MODULES(NEEDED, $NEEDED)
  45
  46 have_xdmcp="no"
  47 PKG_CHECK_MODULES(XDMCP, xdmcp,
  48         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  49                 [
  50                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  51                 NEEDED="$NEEDED xdmcp"
  52                 have_xdmcp="yes"
  53                 ],
  54                 [
  55                 XDMCP_CFLAGS=
  56                 XDMCP_LIBS=
  57                 ], [$XDMCP_LIBS]),
  58         [AC_MSG_RESULT(no)])
  59
  60 AC_SUBST(NEEDED)
  61
  62 # Find the xcb-proto protocol descriptions
  63 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  64 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  65 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  66 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  67
  68 # Find the xcb-proto version
  69 XCBPROTO_VERSION=`$PKG_CONFIG --modversion xcb-proto`
  70 AC_SUBST(XCBPROTO_VERSION)
  71
  72 # Find the xcbgen Python package
  73 AC_MSG_CHECKING(XCBPROTO_XCBPYTHONDIR)
  74 XCBPROTO_XCBPYTHONDIR=`$PKG_CONFIG --variable=pythondir xcb-proto`
  75 AC_MSG_RESULT($XCBPROTO_XCBPYTHONDIR)
  76 AC_SUBST(XCBPROTO_XCBPYTHONDIR)
  77
  78 AC_HEADER_STDC
  79 AC_SEARCH_LIBS(getaddrinfo, socket)
  80 AC_SEARCH_LIBS(connect, socket)
  81
  82 have_win32="no"
  83 lt_enable_auto_import=""
  84 case $host_os in
  85 mingw*)
  86         have_win32="yes"
  87         lt_enable_auto_import="-Wl,--enable-auto-import"
  88         ;;
  89 linux*)
  90         AC_DEFINE([HAVE_ABSTRACT_SOCKETS], 1, [Define if your platform supports abstract sockets])
  91         ;;
  92 esac
  93
  94 AC_SUBST(lt_enable_auto_import)
  95 AM_CONDITIONAL([XCB_HAVE_WIN32], [test "x${have_win32}" = "xyes"])
  96
  97 dnl define buffer queue size
  98 AC_ARG_WITH([queue-size],
  99             AC_HELP_STRING([--with-queue-size=SIZE],
 100             [Set the XCB buffer queue size (default is 16384)]),
 101             [xcb_queue_buffer_size="$withval"],
 102             [xcb_queue_buffer_size=16384])
 103 AC_DEFINE_UNQUOTED(XCB_QUEUE_BUFFER_SIZE, [$xcb_queue_buffer_size],
 104                    [XCB buffer queue size])
 105
 106 dnl check for the sockaddr_un.sun_len member
 107 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 108                 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN,1,[Have the sockaddr_un.sun_len member.])],
 109                 [],
 110                 [ #include <sys/types.h>
 111                   #include <sys/un.h>
 112                 ])
 113
 114 dnl check for support for Solaris Trusted Extensions
 115 AC_CHECK_HEADERS([tsol/label.h])
 116 AC_CHECK_FUNCS([is_system_labeled])
 117
 118 dnl check for IOV_MAX, and fall back to UIO_MAXIOV on BSDish systems
 119 AC_CHECK_DECL([IOV_MAX], [],
 120               [AC_CHECK_DECL([UIO_MAXIOV], [AC_DEFINE([IOV_MAX], [UIO_MAXIOV])],
 121                                            [AC_DEFINE([IOV_MAX], [16], [Define if not provided by <limits.h>])],
 122                                            [[#include <sys/uio.h>]])],
 123               [[#include <limits.h>]])
 124
 125 xcbincludedir='${includedir}/xcb'
 126 AC_SUBST(xcbincludedir)
 127
 128 if  test "x$GCC" = xyes ; then
 129     CWARNFLAGS="-Wall -pedantic -Wpointer-arith -Wold-style-definition \
 130                 -Wstrict-prototypes -Wmissing-declarations -Wnested-externs"
 131 else
 132     AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
 133     if test "x$SUNCC" = "xyes"; then
 134         CWARNFLAGS="-v -fd"
 135     fi
 136 fi
 137 AC_SUBST(CWARNFLAGS)
 138
 139 XCB_CHECK_VISIBILITY()
 140
 141 # htmldir is not defined prior to autoconf 2.59c, so on earlier versions
 142 # set an equivalent value.
 143 AC_PREREQ([2.59c], [], [AC_SUBST([htmldir], [m4_ifset([AC_PACKAGE_TARNAME],
 144           ['${datadir}/doc/${PACKAGE_TARNAME}'],
 145           ['${datadir}/doc/${PACKAGE}'])
 146 ])])
 147
 148 XCB_CHECK_DOXYGEN()
 149
 150 AC_CHECK_FUNC(getaddrinfo, [AC_DEFINE(HAVE_GETADDRINFO, 1, [getaddrinfo() function is available])], )
 151
 152 case $host_os in
 153         # darwin through Snow Leopard has poll() but can't be used to poll character devices.
 154         darwin@<:@789@:>@*|darwin10*) ;;
 155         darwin*)
 156                 _ac_xorg_macosx_version_min=""
 157                 if echo $CPPFLAGS $CFLAGS | grep -q mmacosx-version-min ; then
 158                         _ac_xorg_macosx_version_min=`echo $CPPFLAGS $CFLAGS | sed 's/^.*-mmacosx-version-min=\(@<:@^ @:>@*\).*$/\1/'`
 159                 else
 160                         _ac_xorg_macosx_version_min=$MACOSX_DEPLOYMENT_TARGET
 161                 fi
 162                 case $_ac_xorg_macosx_version_min in
 163                         10.@<:@0123456@:>@|10.@<:@0123456@:>@.*) ;;
 164                         *)
 165                                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 166                         ;;
 167                 esac
 168                 unset _ac_xorg_macosx_version_min
 169                 ;;
 170         *)
 171                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 172         ;;
 173 esac
 174
 175 XCB_EXTENSION(Composite, "yes")
 176 XCB_EXTENSION(Damage, "yes")
 177 XCB_EXTENSION(DPMS, "yes")
 178 XCB_EXTENSION(DRI2, "yes")
 179 XCB_EXTENSION(GLX, "yes")
 180 XCB_EXTENSION(RandR, "yes")
 181 XCB_EXTENSION(Record, "yes")
 182 XCB_EXTENSION(Render, "yes")
 183 XCB_EXTENSION(Resource, "yes")
 184 XCB_EXTENSION(Screensaver, "yes")
 185 XCB_EXTENSION(Shape, "yes")
 186 XCB_EXTENSION(Shm, "yes")
 187 XCB_EXTENSION(Sync, "yes")
 188 XCB_EXTENSION(Xevie, "yes")
 189 XCB_EXTENSION(XFixes, "yes")
 190 XCB_EXTENSION(XFree86-DRI, "yes")
 191 XCB_EXTENSION(Xinerama, "yes")
 192 XCB_EXTENSION(XInput, "no")
 193 XCB_EXTENSION(XKB, "yes")
 194 XCB_EXTENSION(Xprint, "yes")
 195 XCB_EXTENSION(SELinux, "no")
 196 XCB_EXTENSION(XTest, "yes")
 197 XCB_EXTENSION(Xv, "yes")
 198 XCB_EXTENSION(XvMC, "yes")
 199
 200 AC_ARG_WITH(launchd, AS_HELP_STRING([--with-launchd], [Build with support for Apple's launchd (default: auto)]), [LAUNCHD=$withval], [LAUNCHD=auto])
 201 if test "x$LAUNCHD" = xauto; then
 202         unset LAUNCHD
 203         AC_CHECK_PROG(LAUNCHD, [launchd], [yes], [no], [$PATH$PATH_SEPARATOR/sbin])
 204 fi
 205
 206 if test "x$LAUNCHD" = xyes ; then
 207         AC_DEFINE(HAVE_LAUNCHD, 1, [launchd support available])
 208 fi
 209
 210 AC_CONFIG_FILES([
 211 Makefile
 212 doc/Makefile
 213 src/Makefile
 214 tests/Makefile
 215 ])
 216
 217 AC_CONFIG_FILES([
 218 xcb.pc
 219 xcb-composite.pc
 220 xcb-damage.pc
 221 xcb-dpms.pc
 222 xcb-dri2.pc
 223 xcb-glx.pc
 224 xcb-randr.pc
 225 xcb-record.pc
 226 xcb-render.pc
 227 xcb-res.pc
 228 xcb-screensaver.pc
 229 xcb-shape.pc
 230 xcb-shm.pc
 231 xcb-sync.pc
 232 xcb-xevie.pc
 233 xcb-xf86dri.pc
 234 xcb-xfixes.pc
 235 xcb-xinerama.pc
 236 xcb-xinput.pc
 237 xcb-xkb.pc
 238 xcb-xprint.pc
 239 xcb-xselinux.pc
 240 xcb-xtest.pc
 241 xcb-xv.pc
 242 xcb-xvmc.pc
 243 ])
 244
 245 AC_CONFIG_FILES([
 246 doc/xcb.doxygen
 247 ])
 248
 249 AC_OUTPUT
 250
 251 dnl Configuration output
 252
 253 echo ""
 254 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 255 echo ""
 256 echo "  Configuration"
 257 echo "    XDM support.........: ${have_xdmcp}"
 258 echo "    Build unit tests....: ${HAVE_CHECK}"
 259 echo "      with html results.: ${HTML_CHECK_RESULT}"
 260 echo "    XCB buffer size.....: ${xcb_queue_buffer_size}"
 261 echo ""
 262 echo "  X11 extensions"
 263 echo "    Composite...........: ${BUILD_COMPOSITE}"
 264 echo "    Damage..............: ${BUILD_DAMAGE}"
 265 echo "    Dpms................: ${BUILD_DPMS}"
 266 echo "    Dri2................: ${BUILD_DRI2}"
 267 echo "    Glx.................: ${BUILD_GLX}"
 268 echo "    Randr...............: ${BUILD_RANDR}"
 269 echo "    Record..............: ${BUILD_RECORD}"
 270 echo "    Render..............: ${BUILD_RENDER}"
 271 echo "    Resource............: ${BUILD_RESOURCE}"
 272 echo "    Screensaver.........: ${BUILD_SCREENSAVER}"
 273 echo "    selinux.............: ${BUILD_SELINUX}"
 274 echo "    Shape...............: ${BUILD_SHAPE}"
 275 echo "    Shm.................: ${BUILD_SHM}"
 276 echo "    Sync................: ${BUILD_SYNC}"
 277 echo "    Xevie...............: ${BUILD_XEVIE}"
 278 echo "    Xfixes..............: ${BUILD_XFIXES}"
 279 echo "    Xfree86-dri.........: ${BUILD_XFREE86_DRI}"
 280 echo "    xinerama............: ${BUILD_XINERAMA}"
 281 echo "    xinput..............: ${BUILD_XINPUT}"
 282 echo "    xkb.................: ${BUILD_XKB}"
 283 echo "    xprint..............: ${BUILD_XPRINT}"
 284 echo "    xtest...............: ${BUILD_XTEST}"
 285 echo "    xv..................: ${BUILD_XV}"
 286 echo "    xvmc................: ${BUILD_XVMC}"
 287 echo ""
 288 echo "  Used CFLAGS:"
 289 echo "    CPPFLAGS............: ${CPPFLAGS}"
 290 echo "    CFLAGS..............: ${CFLAGS}"
 291 echo "    Warning CFLAGS......: ${CWARNFLAGS}"
 292 echo ""
 293 echo "  Installation:"
 294 echo "    Prefix..............: ${prefix}"
 295 echo ""