git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.57)
   5 AC_INIT([libxcb],
   6         1.1.90.1,
   7         [xcb@lists.freedesktop.org])
   8 AC_CONFIG_SRCDIR([xcb.pc.in])
   9 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  10
  11 AM_PATH_PYTHON([2.5])
  12
  13 PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
  14 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
  15
  16 AC_CONFIG_HEADERS([src/config.h])
  17
  18 AC_PROG_LIBTOOL
  19 AC_PROG_CC
  20
  21 AC_PATH_PROG(XSLTPROC, xsltproc, no)
  22 if test "$XSLTPROC" = "no"; then
  23    AC_MSG_ERROR([XCB requires xsltproc.])
  24 fi
  25
  26 HTML_CHECK_RESULT=false
  27 if test x"$HAVE_CHECK" = xyes; then
  28         if test x"$XSLTPROC" != xno; then
  29                 HTML_CHECK_RESULT=true
  30         fi
  31 fi
  32 AC_SUBST(HTML_CHECK_RESULT)
  33
  34 # Checks for pkg-config packages
  35 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.1)
  36 NEEDED="pthread-stubs xau >= 0.99.2"
  37 PKG_CHECK_MODULES(NEEDED, $NEEDED)
  38
  39 have_xdmcp="no"
  40 PKG_CHECK_MODULES(XDMCP, xdmcp,
  41         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  42                 [
  43                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  44                 NEEDED="$NEEDED xdmcp"
  45                 have_xdmcp="yes"
  46                 ],
  47                 [
  48                 XDMCP_CFLAGS=
  49                 XDMCP_LIBS=
  50                 ], [$XDMCP_LIBS]),
  51         [AC_MSG_RESULT(no)])
  52
  53 AC_CHECK_HEADER([execinfo.h], [AC_DEFINE(HAVE_BACKTRACE,1,[Has backtrace*() needed for retrieving stack traces])])
  54
  55 AC_SUBST(NEEDED)
  56
  57 # Find the xcb-proto protocol descriptions
  58 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  59 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  60 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  61 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  62
  63 # Find the xcbgen Python package
  64 AC_MSG_CHECKING(XCBPROTO_XCBPYTHONDIR)
  65 XCBPROTO_XCBPYTHONDIR=`$PKG_CONFIG --variable=pythondir xcb-proto`
  66 AC_MSG_RESULT($XCBPROTO_XCBPYTHONDIR)
  67 AC_SUBST(XCBPROTO_XCBPYTHONDIR)
  68
  69 AC_HEADER_STDC
  70 AC_SEARCH_LIBS(getaddrinfo, socket)
  71 AC_SEARCH_LIBS(connect, socket)
  72
  73 dnl check for the sockaddr_un.sun_len member
  74 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
  75                 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN,1,[Have the sockaddr_un.sun_len member.])],
  76                 [],
  77                 [ #include <sys/types.h>
  78                   #include <sys/un.h>
  79                 ])
  80
  81 xcbincludedir='${includedir}/xcb'
  82 AC_SUBST(xcbincludedir)
  83
  84 if  test "x$GCC" = xyes ; then
  85     CWARNFLAGS="-Wall -pedantic -Wpointer-arith \
  86                 -Wstrict-prototypes -Wmissing-declarations -Wnested-externs"
  87 else
  88     AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  89     if test "x$SUNCC" = "xyes"; then
  90         CWARNFLAGS="-v"
  91     fi
  92 fi
  93 AC_SUBST(CWARNFLAGS)
  94
  95 XCB_CHECK_VISIBILITY()
  96
  97 # htmldir is not defined prior to autoconf 2.59c, so on earlier versions
  98 # set an equivalent value.
  99 AC_PREREQ([2.59c], [], [AC_SUBST([htmldir], [m4_ifset([AC_PACKAGE_TARNAME],
 100           ['${datadir}/doc/${PACKAGE_TARNAME}'],
 101           ['${datadir}/doc/${PACKAGE}'])
 102 ])])
 103
 104 XCB_CHECK_DOXYGEN()
 105
 106 XCB_EXTENSION(Composite, "yes")
 107 XCB_EXTENSION(Damage, "yes")
 108 XCB_EXTENSION(DPMS, "yes")
 109 XCB_EXTENSION(GLX, "yes")
 110 XCB_EXTENSION(RandR, "yes")
 111 XCB_EXTENSION(Record, "yes")
 112 XCB_EXTENSION(Render, "yes")
 113 XCB_EXTENSION(Resource, "yes")
 114 XCB_EXTENSION(Screensaver, "yes")
 115 XCB_EXTENSION(Shape, "yes")
 116 XCB_EXTENSION(Shm, "yes")
 117 XCB_EXTENSION(Sync, "yes")
 118 XCB_EXTENSION(Xevie, "yes")
 119 XCB_EXTENSION(XFixes, "yes")
 120 XCB_EXTENSION(XFree86-DRI, "yes")
 121 XCB_EXTENSION(Xinerama, "yes")
 122 XCB_EXTENSION(XInput, "no")
 123 XCB_EXTENSION(Xprint, "yes")
 124 XCB_EXTENSION(SELinux, "no")
 125 XCB_EXTENSION(XTest, "yes")
 126 XCB_EXTENSION(Xv, "yes")
 127 XCB_EXTENSION(XvMC, "yes")
 128 XCB_EXTENSION(Composite, "yes")
 129 XCB_EXTENSION(Composite, "yes")
 130
 131
 132 AC_CONFIG_FILES([
 133 Makefile
 134 doc/Makefile
 135 src/Makefile
 136 tests/Makefile
 137 ])
 138
 139 AC_CONFIG_FILES([
 140 xcb.pc
 141 xcb-xlib.pc
 142 xcb-composite.pc
 143 xcb-damage.pc
 144 xcb-dpms.pc
 145 xcb-glx.pc
 146 xcb-randr.pc
 147 xcb-record.pc
 148 xcb-render.pc
 149 xcb-res.pc
 150 xcb-screensaver.pc
 151 xcb-shape.pc
 152 xcb-shm.pc
 153 xcb-sync.pc
 154 xcb-xevie.pc
 155 xcb-xf86dri.pc
 156 xcb-xfixes.pc
 157 xcb-xinerama.pc
 158 xcb-xinput.pc
 159 xcb-xprint.pc
 160 xcb-xselinux.pc
 161 xcb-xtest.pc
 162 xcb-xv.pc
 163 xcb-xvmc.pc
 164 ])
 165
 166 AC_CONFIG_FILES([
 167 doc/xcb.doxygen
 168 ])
 169
 170 AC_OUTPUT
 171
 172 dnl Configuration output
 173
 174 echo ""
 175 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 176 echo ""
 177 echo "  Configuration"
 178 echo "    XDM support.........: ${have_xdmcp}"
 179 echo "    Build unit tests....: ${HAVE_CHECK}"
 180 echo ""
 181 echo "  Used CFLAGS:"
 182 echo "    CPPFLAGS............: ${CPPFLAGS}"
 183 echo "    CFLAGS..............: ${CFLAGS}"
 184 echo "    Warning CFLAGS......: ${CWARNFLAGS}"
 185 echo ""
 186 echo "  Installation:"
 187 echo "    Prefix..............: ${prefix}"
 188 echo ""