git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.57)
   5 AC_INIT([libxcb],
   6         1.7,
   7         [xcb@lists.freedesktop.org])
   8 AC_CONFIG_SRCDIR([xcb.pc.in])
   9 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  10 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  11
  12 AM_PATH_PYTHON([2.6])
  13
  14 PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
  15 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
  16
  17 AC_CONFIG_HEADERS([src/config.h])
  18
  19 AC_LIBTOOL_WIN32_DLL
  20 AC_PROG_LIBTOOL
  21 AC_PROG_CC
  22
  23 AC_PATH_PROG(XSLTPROC, xsltproc, no)
  24 if test "$XSLTPROC" = "no"; then
  25    AC_MSG_ERROR([XCB requires xsltproc.])
  26 fi
  27
  28 HTML_CHECK_RESULT=false
  29 if test x"$HAVE_CHECK" = xyes; then
  30         if test x"$XSLTPROC" != xno; then
  31                 HTML_CHECK_RESULT=true
  32         fi
  33 fi
  34 AC_SUBST(HTML_CHECK_RESULT)
  35
  36 # Checks for pkg-config packages
  37 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.6)
  38 NEEDED="pthread-stubs xau >= 0.99.2"
  39 PKG_CHECK_MODULES(NEEDED, $NEEDED)
  40
  41 have_xdmcp="no"
  42 PKG_CHECK_MODULES(XDMCP, xdmcp,
  43         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  44                 [
  45                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  46                 NEEDED="$NEEDED xdmcp"
  47                 have_xdmcp="yes"
  48                 ],
  49                 [
  50                 XDMCP_CFLAGS=
  51                 XDMCP_LIBS=
  52                 ], [$XDMCP_LIBS]),
  53         [AC_MSG_RESULT(no)])
  54
  55 AC_SUBST(NEEDED)
  56
  57 # Find the xcb-proto protocol descriptions
  58 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  59 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  60 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  61 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  62
  63 # Find the xcb-proto version
  64 XCBPROTO_VERSION=`$PKG_CONFIG --modversion xcb-proto`
  65 AC_SUBST(XCBPROTO_VERSION)
  66
  67 # Find the xcbgen Python package
  68 AC_MSG_CHECKING(XCBPROTO_XCBPYTHONDIR)
  69 XCBPROTO_XCBPYTHONDIR=`$PKG_CONFIG --variable=pythondir xcb-proto`
  70 AC_MSG_RESULT($XCBPROTO_XCBPYTHONDIR)
  71 AC_SUBST(XCBPROTO_XCBPYTHONDIR)
  72
  73 AC_HEADER_STDC
  74 AC_SEARCH_LIBS(getaddrinfo, socket)
  75 AC_SEARCH_LIBS(connect, socket)
  76
  77 have_win32="no"
  78 lt_enable_auto_import=""
  79 case $host_os in
  80 mingw*)
  81         have_win32="yes"
  82         lt_enable_auto_import="-Wl,--enable-auto-import"
  83         ;;
  84 linux*)
  85         AC_DEFINE([HAVE_ABSTRACT_SOCKETS], 1, [Define if your platform supports abstract sockets])
  86         ;;
  87 esac
  88
  89 AC_SUBST(lt_enable_auto_import)
  90 AM_CONDITIONAL([XCB_HAVE_WIN32], [test "x${have_win32}" = "xyes"])
  91
  92 dnl define buffer queue size
  93 AC_ARG_WITH([queue-size],
  94             AC_HELP_STRING([--with-queue-size=SIZE],
  95             [Set the XCB buffer queue size (default is 16384)]),
  96             [xcb_queue_buffer_size="$withval"],
  97             [xcb_queue_buffer_size=16384])
  98 AC_DEFINE_UNQUOTED(XCB_QUEUE_BUFFER_SIZE, [$xcb_queue_buffer_size],
  99                    [XCB buffer queue size])
 100
 101 dnl check for the sockaddr_un.sun_len member
 102 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 103                 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN,1,[Have the sockaddr_un.sun_len member.])],
 104                 [],
 105                 [ #include <sys/types.h>
 106                   #include <sys/un.h>
 107                 ])
 108
 109 dnl check for support for Solaris Trusted Extensions
 110 AC_CHECK_HEADERS([tsol/label.h])
 111 AC_CHECK_FUNCS([is_system_labeled])
 112
 113 xcbincludedir='${includedir}/xcb'
 114 AC_SUBST(xcbincludedir)
 115
 116 if  test "x$GCC" = xyes ; then
 117     CWARNFLAGS="-Wall -pedantic -Wpointer-arith \
 118                 -Wstrict-prototypes -Wmissing-declarations -Wnested-externs"
 119 else
 120     AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
 121     if test "x$SUNCC" = "xyes"; then
 122         CWARNFLAGS="-v"
 123     fi
 124 fi
 125 AC_SUBST(CWARNFLAGS)
 126
 127 XCB_CHECK_VISIBILITY()
 128
 129 # htmldir is not defined prior to autoconf 2.59c, so on earlier versions
 130 # set an equivalent value.
 131 AC_PREREQ([2.59c], [], [AC_SUBST([htmldir], [m4_ifset([AC_PACKAGE_TARNAME],
 132           ['${datadir}/doc/${PACKAGE_TARNAME}'],
 133           ['${datadir}/doc/${PACKAGE}'])
 134 ])])
 135
 136 XCB_CHECK_DOXYGEN()
 137
 138 case $host_os in
 139         # darwin through Snow Leopard has poll() but can't be used to poll character devices.
 140         darwin@<:@789@:>@*|darwin10*) ;;
 141         darwin*)
 142                 _ac_xorg_macosx_version_min=""
 143                 if echo $CPPFLAGS $CFLAGS | grep -q mmacosx-version-min ; then
 144                         _ac_xorg_macosx_version_min=`echo $CPPFLAGS $CFLAGS | sed 's/^.*-mmacosx-version-min=\(@<:@^ @:>@*\).*$/\1/'`
 145                 else
 146                         _ac_xorg_macosx_version_min=$MACOSX_DEPLOYMENT_TARGET
 147                 fi
 148                 case $_ac_xorg_macosx_version_min in
 149                         10.@<:@0123456@:>@|10.@<:@0123456@:>@.*) ;;
 150                         *)
 151                                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 152                         ;;
 153                 esac
 154                 unset _ac_xorg_macosx_version_min
 155                 ;;
 156         *)
 157                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 158         ;;
 159 esac
 160
 161 XCB_EXTENSION(Composite, "yes")
 162 XCB_EXTENSION(Damage, "yes")
 163 XCB_EXTENSION(DPMS, "yes")
 164 XCB_EXTENSION(DRI2, "yes")
 165 XCB_EXTENSION(GLX, "yes")
 166 XCB_EXTENSION(RandR, "yes")
 167 XCB_EXTENSION(Record, "yes")
 168 XCB_EXTENSION(Render, "yes")
 169 XCB_EXTENSION(Resource, "yes")
 170 XCB_EXTENSION(Screensaver, "yes")
 171 XCB_EXTENSION(Shape, "yes")
 172 XCB_EXTENSION(Shm, "yes")
 173 XCB_EXTENSION(Sync, "yes")
 174 XCB_EXTENSION(Xevie, "yes")
 175 XCB_EXTENSION(XFixes, "yes")
 176 XCB_EXTENSION(XFree86-DRI, "yes")
 177 XCB_EXTENSION(Xinerama, "yes")
 178 XCB_EXTENSION(XInput, "no")
 179 XCB_EXTENSION(XKB, "no")
 180 XCB_EXTENSION(Xprint, "yes")
 181 XCB_EXTENSION(SELinux, "no")
 182 XCB_EXTENSION(XTest, "yes")
 183 XCB_EXTENSION(Xv, "yes")
 184 XCB_EXTENSION(XvMC, "yes")
 185
 186 AC_ARG_WITH(launchd, AS_HELP_STRING([--with-launchd], [Build with support for Apple's launchd (default: auto)]), [LAUNCHD=$withval], [LAUNCHD=auto])
 187 if test "x$LAUNCHD" = xauto; then
 188         unset LAUNCHD
 189         AC_CHECK_PROG(LAUNCHD, [launchd], [yes], [no], [$PATH$PATH_SEPARATOR/sbin])
 190 fi
 191
 192 if test "x$LAUNCHD" = xyes ; then
 193         AC_DEFINE(HAVE_LAUNCHD, 1, [launchd support available])
 194 fi
 195
 196 AC_CONFIG_FILES([
 197 Makefile
 198 doc/Makefile
 199 src/Makefile
 200 tests/Makefile
 201 ])
 202
 203 AC_CONFIG_FILES([
 204 xcb.pc
 205 xcb-composite.pc
 206 xcb-damage.pc
 207 xcb-dpms.pc
 208 xcb-dri2.pc
 209 xcb-glx.pc
 210 xcb-randr.pc
 211 xcb-record.pc
 212 xcb-render.pc
 213 xcb-res.pc
 214 xcb-screensaver.pc
 215 xcb-shape.pc
 216 xcb-shm.pc
 217 xcb-sync.pc
 218 xcb-xevie.pc
 219 xcb-xf86dri.pc
 220 xcb-xfixes.pc
 221 xcb-xinerama.pc
 222 xcb-xinput.pc
 223 xcb-xkb.pc
 224 xcb-xprint.pc
 225 xcb-xselinux.pc
 226 xcb-xtest.pc
 227 xcb-xv.pc
 228 xcb-xvmc.pc
 229 ])
 230
 231 AC_CONFIG_FILES([
 232 doc/xcb.doxygen
 233 ])
 234
 235 AC_OUTPUT
 236
 237 dnl Configuration output
 238
 239 echo ""
 240 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 241 echo ""
 242 echo "  Configuration"
 243 echo "    XDM support.........: ${have_xdmcp}"
 244 echo "    Build unit tests....: ${HAVE_CHECK}"
 245 echo "    XCB buffer size.....: ${xcb_queue_buffer_size}"
 246 echo ""
 247 echo "  X11 extensions"
 248 echo "    Composite...........: ${BUILD_COMPOSITE}"
 249 echo "    Damage..............: ${BUILD_DAMAGE}"
 250 echo "    Dpms................: ${BUILD_DPMS}"
 251 echo "    Dri2................: ${BUILD_DRI2}"
 252 echo "    Glx.................: ${BUILD_GLX}"
 253 echo "    Randr...............: ${BUILD_RANDR}"
 254 echo "    Record..............: ${BUILD_RECORD}"
 255 echo "    Render..............: ${BUILD_RENDER}"
 256 echo "    Resource............: ${BUILD_RESOURCE}"
 257 echo "    Screensaver.........: ${BUILD_SCREENSAVER}"
 258 echo "    selinux.............: ${BUILD_SELINUX}"
 259 echo "    Shape...............: ${BUILD_SHAPE}"
 260 echo "    Shm.................: ${BUILD_SHM}"
 261 echo "    Sync................: ${BUILD_SYNC}"
 262 echo "    Xevie...............: ${BUILD_XEVIE}"
 263 echo "    Xfixes..............: ${BUILD_XFIXES}"
 264 echo "    Xfree86-dri.........: ${BUILD_XFREE86_DRI}"
 265 echo "    xinerama............: ${BUILD_XINERAMA}"
 266 echo "    xinput..............: ${BUILD_XINPUT}"
 267 echo "    xkb.................: ${BUILD_XKB}"
 268 echo "    xprint..............: ${BUILD_XPRINT}"
 269 echo "    xtest...............: ${BUILD_XTEST}"
 270 echo "    xv..................: ${BUILD_XV}"
 271 echo "    xvmc................: ${BUILD_XVMC}"
 272 echo ""
 273 echo "  Used CFLAGS:"
 274 echo "    CPPFLAGS............: ${CPPFLAGS}"
 275 echo "    CFLAGS..............: ${CFLAGS}"
 276 echo "    Warning CFLAGS......: ${CWARNFLAGS}"
 277 echo ""
 278 echo "  Installation:"
 279 echo "    Prefix..............: ${prefix}"
 280 echo ""