git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.57)
   5 AC_INIT([libxcb],
   6         1.1.90.1,
   7         [xcb@lists.freedesktop.org])
   8 AC_CONFIG_SRCDIR([xcb.pc.in])
   9 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  10
  11 AM_PATH_PYTHON([2.5])
  12
  13 PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
  14 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
  15
  16 AC_CONFIG_HEADERS([src/config.h])
  17
  18 AC_PROG_LIBTOOL
  19 AC_PROG_CC
  20
  21 AC_PATH_PROG(XSLTPROC, xsltproc, no)
  22 if test "$XSLTPROC" = "no"; then
  23    AC_MSG_ERROR([XCB requires xsltproc.])
  24 fi
  25
  26 HTML_CHECK_RESULT=false
  27 if test x"$HAVE_CHECK" = xyes; then
  28         if test x"$XSLTPROC" != xno; then
  29                 HTML_CHECK_RESULT=true
  30         fi
  31 fi
  32 AC_SUBST(HTML_CHECK_RESULT)
  33
  34 # Checks for pkg-config packages
  35 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.1)
  36 NEEDED="pthread-stubs xau >= 0.99.2"
  37 PKG_CHECK_MODULES(NEEDED, $NEEDED)
  38
  39 have_xdmcp="no"
  40 PKG_CHECK_MODULES(XDMCP, xdmcp,
  41         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  42                 [
  43                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  44                 NEEDED="$NEEDED xdmcp"
  45                 have_xdmcp="yes"
  46                 ],
  47                 [
  48                 XDMCP_CFLAGS=
  49                 XDMCP_LIBS=
  50                 ], [$XDMCP_LIBS]),
  51         [AC_MSG_RESULT(no)])
  52
  53 AC_CHECK_HEADER([execinfo.h], [AC_DEFINE(HAVE_BACKTRACE,1,[Has backtrace*() needed for retrieving stack traces])])
  54
  55 AC_SUBST(NEEDED)
  56
  57 # Find the xcb-proto protocol descriptions
  58 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  59 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  60 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  61 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  62
  63 # Find the xcbgen Python package
  64 AC_MSG_CHECKING(XCBPROTO_XCBPYTHONDIR)
  65 XCBPROTO_XCBPYTHONDIR=`$PKG_CONFIG --variable=pythondir xcb-proto`
  66 AC_MSG_RESULT($XCBPROTO_XCBPYTHONDIR)
  67 AC_SUBST(XCBPROTO_XCBPYTHONDIR)
  68
  69 AC_HEADER_STDC
  70 AC_SEARCH_LIBS(getaddrinfo, socket)
  71 AC_SEARCH_LIBS(connect, socket)
  72
  73 case $host_os in
  74 linux*)
  75         AC_DEFINE([HAVE_ABSTRACT_SOCKETS], 1, [Define if your platform supports abstract sockets])
  76         ;;
  77 esac
  78
  79 dnl check for the sockaddr_un.sun_len member
  80 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
  81                 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN,1,[Have the sockaddr_un.sun_len member.])],
  82                 [],
  83                 [ #include <sys/types.h>
  84                   #include <sys/un.h>
  85                 ])
  86
  87 xcbincludedir='${includedir}/xcb'
  88 AC_SUBST(xcbincludedir)
  89
  90 if  test "x$GCC" = xyes ; then
  91     CWARNFLAGS="-Wall -pedantic -Wpointer-arith \
  92                 -Wstrict-prototypes -Wmissing-declarations -Wnested-externs"
  93 else
  94     AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  95     if test "x$SUNCC" = "xyes"; then
  96         CWARNFLAGS="-v"
  97     fi
  98 fi
  99 AC_SUBST(CWARNFLAGS)
 100
 101 XCB_CHECK_VISIBILITY()
 102
 103 # htmldir is not defined prior to autoconf 2.59c, so on earlier versions
 104 # set an equivalent value.
 105 AC_PREREQ([2.59c], [], [AC_SUBST([htmldir], [m4_ifset([AC_PACKAGE_TARNAME],
 106           ['${datadir}/doc/${PACKAGE_TARNAME}'],
 107           ['${datadir}/doc/${PACKAGE}'])
 108 ])])
 109
 110 XCB_CHECK_DOXYGEN()
 111
 112 XCB_EXTENSION(Composite, "yes")
 113 XCB_EXTENSION(Damage, "yes")
 114 XCB_EXTENSION(DPMS, "yes")
 115 XCB_EXTENSION(GLX, "yes")
 116 XCB_EXTENSION(RandR, "yes")
 117 XCB_EXTENSION(Record, "yes")
 118 XCB_EXTENSION(Render, "yes")
 119 XCB_EXTENSION(Resource, "yes")
 120 XCB_EXTENSION(Screensaver, "yes")
 121 XCB_EXTENSION(Shape, "yes")
 122 XCB_EXTENSION(Shm, "yes")
 123 XCB_EXTENSION(Sync, "yes")
 124 XCB_EXTENSION(Xevie, "yes")
 125 XCB_EXTENSION(XFixes, "yes")
 126 XCB_EXTENSION(XFree86-DRI, "yes")
 127 XCB_EXTENSION(Xinerama, "yes")
 128 XCB_EXTENSION(XInput, "no")
 129 XCB_EXTENSION(Xprint, "yes")
 130 XCB_EXTENSION(SELinux, "no")
 131 XCB_EXTENSION(XTest, "yes")
 132 XCB_EXTENSION(Xv, "yes")
 133 XCB_EXTENSION(XvMC, "yes")
 134 XCB_EXTENSION(Composite, "yes")
 135 XCB_EXTENSION(Composite, "yes")
 136
 137
 138 AC_CONFIG_FILES([
 139 Makefile
 140 doc/Makefile
 141 src/Makefile
 142 tests/Makefile
 143 ])
 144
 145 AC_CONFIG_FILES([
 146 xcb.pc
 147 xcb-xlib.pc
 148 xcb-composite.pc
 149 xcb-damage.pc
 150 xcb-dpms.pc
 151 xcb-glx.pc
 152 xcb-randr.pc
 153 xcb-record.pc
 154 xcb-render.pc
 155 xcb-res.pc
 156 xcb-screensaver.pc
 157 xcb-shape.pc
 158 xcb-shm.pc
 159 xcb-sync.pc
 160 xcb-xevie.pc
 161 xcb-xf86dri.pc
 162 xcb-xfixes.pc
 163 xcb-xinerama.pc
 164 xcb-xinput.pc
 165 xcb-xprint.pc
 166 xcb-xselinux.pc
 167 xcb-xtest.pc
 168 xcb-xv.pc
 169 xcb-xvmc.pc
 170 ])
 171
 172 AC_CONFIG_FILES([
 173 doc/xcb.doxygen
 174 ])
 175
 176 AC_OUTPUT
 177
 178 dnl Configuration output
 179
 180 echo ""
 181 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 182 echo ""
 183 echo "  Configuration"
 184 echo "    XDM support.........: ${have_xdmcp}"
 185 echo "    Build unit tests....: ${HAVE_CHECK}"
 186 echo ""
 187 echo "  Used CFLAGS:"
 188 echo "    CPPFLAGS............: ${CPPFLAGS}"
 189 echo "    CFLAGS..............: ${CFLAGS}"
 190 echo "    Warning CFLAGS......: ${CWARNFLAGS}"
 191 echo ""
 192 echo "  Installation:"
 193 echo "    Prefix..............: ${prefix}"
 194 echo ""