git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.57)
   5 AC_INIT([libxcb],
   6         0.9.92,
   7         [xcb@lists.freedesktop.org])
   8 AC_CONFIG_SRCDIR([xcb.pc.in])
   9 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  10
  11 dnl This ifdef has no useful effect prior to automake 1.9, but in 1.9
  12 dnl it allows the user to not have check.m4 installed.
  13 m4_ifdef([AM_PATH_CHECK],[
  14 AM_PATH_CHECK(0.8.2, [HAVE_CHECK=true], [HAVE_CHECK=false])
  15 ])
  16 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xtrue)
  17
  18 AC_CONFIG_HEADERS([src/config.h])
  19
  20 AC_PROG_LIBTOOL
  21 AC_PROG_CC
  22
  23 AC_PATH_PROG(XSLTPROC, xsltproc, no)
  24 if test "$XSLTPROC" = "no"; then
  25    AC_MSG_ERROR([XCB requires xsltproc.])
  26 fi
  27
  28 HTML_CHECK_RESULT=false
  29 if test x"$HAVE_CHECK" = xtrue; then
  30         if test x"$XSLTPROC" != xno; then
  31                 HTML_CHECK_RESULT=true
  32         fi
  33 fi
  34 AC_SUBST(HTML_CHECK_RESULT)
  35
  36 # Checks for pkg-config packages
  37 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 0.9.92)
  38 PKG_CHECK_MODULES(XAU, xau)
  39
  40 PKG_CHECK_MODULES(XDMCP, xdmcp,
  41         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  42                 [
  43                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  44                 ],
  45                 [
  46                 XDMCP_CFLAGS=
  47                 XDMCP_LIBS=
  48                 ], [$XDMCP_LIBS]),
  49         [AC_MSG_RESULT(no)])
  50
  51 # Find the xcb-proto protocol descriptions
  52 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  53 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  54 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  55 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  56
  57 AC_HEADER_STDC
  58 AC_SEARCH_LIBS(gethostbyname, nsl)
  59 AC_SEARCH_LIBS(connect, socket)
  60
  61 xcbincludedir='${includedir}/xcb'
  62 AC_SUBST(xcbincludedir)
  63
  64 AC_ARG_WITH(opt,
  65 AC_HELP_STRING([--with-opt],       [compile with reasonable optimizations])
  66 AC_HELP_STRING([--with-opt=FLAGS], [compile with specified FLAGS])
  67 AC_HELP_STRING([--with-opt=small], [compile for smallest code])
  68 AC_HELP_STRING([--without-opt],    [compile without optimization (default)]),
  69 [
  70         case "$withval" in
  71         yes)
  72                 COPTFLAGS="-O3"
  73                 ;;
  74         small)
  75                 COPTFLAGS="-Os -fomit-frame-pointer -DNDEBUG"
  76                 ;;
  77         no)
  78                 COPTFLAGS=""
  79                 ;;
  80         *)
  81                 COPTFLAGS="$withval"
  82                 ;;
  83         esac
  84 ])
  85 AC_CACHE_CHECK([what compiler optimizations to apply], [COPTFLAGS], [COPTFLAGS=""])
  86 AC_SUBST(COPTFLAGS)
  87
  88 AC_ARG_WITH(debug,
  89 AC_HELP_STRING([--with-debug],       [compile with debugging (default)])
  90 AC_HELP_STRING([--with-debug=FLAGS], [compile with specified debugging FLAGS])
  91 AC_HELP_STRING([--without-debug],    [compile without debugging]),
  92 [
  93         case "$withval" in
  94         yes)
  95                 CDEBUGFLAGS="-g"
  96                 ;;
  97         no)
  98                 CDEBUGFLAGS=""
  99                 ;;
 100         *)
 101                 CDEBUGFLAGS="$withval"
 102                 ;;
 103         esac
 104 ])
 105 AC_CACHE_CHECK([what debugging options to apply], [CDEBUGFLAGS], [CDEBUGFLAGS="-g"])
 106 AC_SUBST(CDEBUGFLAGS)
 107
 108 if  test "x$GCC" = xyes ; then
 109     CWARNFLAGS="-Wall -pedantic -Wpointer-arith \
 110                 -Wstrict-prototypes -Wmissing-declarations -Wnested-externs"
 111 else
 112     AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
 113     if test "x$SUNCC" = "xyes"; then
 114         CWARNFLAGS="-v"
 115     fi
 116 fi
 117 AC_SUBST(CWARNFLAGS)
 118
 119 GCC_CHECK_VISIBILITY()
 120
 121 AM_CHECK_DOXYGEN()
 122
 123 AC_CONFIG_FILES([Makefile src/Makefile tests/Makefile doc/Makefile])
 124 AC_CONFIG_FILES([xcb.pc xcb-xlib.pc xcb-composite.pc xcb-damage.pc xcb-dpms.pc xcb-glx.pc xcb-randr.pc xcb-record.pc xcb-render.pc xcb-res.pc xcb-screensaver.pc xcb-shape.pc xcb-shm.pc xcb-sync.pc xcb-xevie.pc xcb-xf86dri.pc xcb-xfixes.pc xcb-xinerama.pc xcb-xprint.pc xcb-xtest.pc xcb-xv.pc xcb-xvmc.pc])
 125
 126 AC_OUTPUT