git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 # Initialize Autoconf
   4 AC_PREREQ([2.60])
   5 AC_INIT([libxcb],[1.10],
   6         [https://bugs.freedesktop.org/enter_bug.cgi?product=xcb],
   7         [libxcb])
   8 AC_CONFIG_AUX_DIR([build-aux])
   9 AC_CONFIG_MACRO_DIR([m4])
  10 AC_CONFIG_SRCDIR([xcb.pc.in])
  11 AC_CONFIG_HEADERS([src/config.h])
  12
  13 # Initialize Automake
  14 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  15 AM_PATH_PYTHON([2.6])
  16
  17 # Set common system defines for POSIX extensions, such as _GNU_SOURCE
  18 # Must be called before any macros that run the compiler (like AC_PROG_LIBTOOL)
  19 # to avoid autoconf errors.
  20 AC_USE_SYSTEM_EXTENSIONS
  21
  22 # Initialize libtool
  23 LT_PREREQ([2.2])
  24 LT_INIT([win32-dll])
  25
  26 # Require xorg-macros minimum of 1.18 - Initial version
  27 m4_ifndef([XORG_MACROS_VERSION],
  28           [m4_fatal([must install xorg-macros 1.18 or later before running autoconf/autogen])])
  29 XORG_MACROS_VERSION(1.18)
  30 XORG_DEFAULT_OPTIONS
  31 XORG_ENABLE_DEVEL_DOCS
  32 XORG_WITH_DOXYGEN
  33
  34 # The dot drawing tool is checked by XORG_WITH_DOXYGEN, needed for xcb manual
  35 if test x"$HAVE_DOT" = xno; then
  36     AC_MSG_WARN([dot not found - doxygen targets will be skipped])
  37 fi
  38
  39 PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
  40 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
  41
  42 XSLTPROC=no
  43 HTML_CHECK_RESULT=no
  44 if test x"$HAVE_CHECK" = xyes; then
  45         AC_PATH_PROG(XSLTPROC, xsltproc, no)
  46         if test x"$XSLTPROC" != xno; then
  47                 HTML_CHECK_RESULT=yes
  48         fi
  49 fi
  50 AC_SUBST(HTML_CHECK_RESULT)
  51
  52 # Checks for pkg-config packages
  53 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.10)
  54 NEEDED="pthread-stubs xau >= 0.99.2"
  55 PKG_CHECK_MODULES(NEEDED, $NEEDED)
  56
  57 have_xdmcp="no"
  58 PKG_CHECK_MODULES(XDMCP, xdmcp,
  59         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  60                 [
  61                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  62                 NEEDED="$NEEDED xdmcp"
  63                 have_xdmcp="yes"
  64                 ],
  65                 [
  66                 XDMCP_CFLAGS=
  67                 XDMCP_LIBS=
  68                 ], [$XDMCP_LIBS]),
  69         [AC_MSG_RESULT(no)])
  70
  71 AC_SUBST(NEEDED)
  72
  73 # Find the xcb-proto protocol descriptions
  74 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  75 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  76 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  77 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  78
  79 # Find the xcb-proto version
  80 XCBPROTO_VERSION=`$PKG_CONFIG --modversion xcb-proto`
  81 AC_SUBST(XCBPROTO_VERSION)
  82
  83 # Find the xcbgen Python package
  84 AC_MSG_CHECKING(XCBPROTO_XCBPYTHONDIR)
  85 XCBPROTO_XCBPYTHONDIR=`$PKG_CONFIG --variable=pythondir xcb-proto`
  86 AC_MSG_RESULT($XCBPROTO_XCBPYTHONDIR)
  87 AC_SUBST(XCBPROTO_XCBPYTHONDIR)
  88
  89 AC_HEADER_STDC
  90 AC_SEARCH_LIBS(getaddrinfo, socket)
  91 AC_SEARCH_LIBS(connect, socket)
  92
  93 AC_ARG_ENABLE(sendfds, AS_HELP_STRING([--disable-sendfds], [Support FD passing (default: auto)]),
  94               [sendfds=$enableval], [sendfds=auto])
  95
  96 case x$sendfds in
  97 xauto)
  98         AC_SEARCH_LIBS(sendmsg, socket, [sendfds="yes"], [sendfds="no"])
  99         ;;
 100 esac
 101
 102 # XPG4v2/UNIX95 added msg_control - check to see if we need to define
 103 # _XOPEN_SOURCE to get it (such as on Solaris)
 104 AC_CHECK_MEMBER([struct msghdr.msg_control], [], [],
 105                  [
 106 AC_INCLUDES_DEFAULT
 107 #include <sys/socket.h>
 108                  ])
 109 # First try for Solaris in C99 compliant mode, which requires XPG6/UNIX03
 110 if test "x$ac_cv_member_struct_msghdr_msg_control" = xno; then
 111     unset ac_cv_member_struct_msghdr_msg_control
 112     AC_MSG_NOTICE([trying again with _XOPEN_SOURCE=600])
 113     AC_CHECK_MEMBER([struct msghdr.msg_control],
 114                     [AC_DEFINE([_XOPEN_SOURCE], [600],
 115                        [Defined if needed to expose struct msghdr.msg_control])
 116                     ], [], [
 117 #define _XOPEN_SOURCE 600
 118 AC_INCLUDES_DEFAULT
 119 #include <sys/socket.h>
 120                      ])
 121 fi
 122 # If that didn't work, fall back to XPG5/UNIX98 with C89
 123 if test "x$ac_cv_member_struct_msghdr_msg_control" = xno; then
 124     unset ac_cv_member_struct_msghdr_msg_control
 125     AC_MSG_NOTICE([trying again with _XOPEN_SOURCE=500])
 126     AC_CHECK_MEMBER([struct msghdr.msg_control],
 127                     [AC_DEFINE([_XOPEN_SOURCE], [500],
 128                        [Defined if needed to expose struct msghdr.msg_control])
 129                     ], [sendfds="no"], [
 130 #define _XOPEN_SOURCE 500
 131 AC_INCLUDES_DEFAULT
 132 #include <sys/socket.h>
 133                      ])
 134 fi
 135
 136 case x$sendfds in
 137 xyes)
 138         AC_DEFINE([HAVE_SENDMSG],1,[Define if your platform supports sendmsg])
 139         ;;
 140 esac
 141
 142 have_win32="no"
 143 lt_enable_auto_import=""
 144 case $host_os in
 145 mingw*)
 146         have_win32="yes"
 147         lt_enable_auto_import="-Wl,--enable-auto-import"
 148         ;;
 149 linux*)
 150         AC_DEFINE([HAVE_ABSTRACT_SOCKETS], 1, [Define if your platform supports abstract sockets])
 151         ;;
 152 esac
 153
 154 AC_SUBST(lt_enable_auto_import)
 155 AM_CONDITIONAL([XCB_HAVE_WIN32], [test "x${have_win32}" = "xyes"])
 156
 157 dnl define buffer queue size
 158 AC_ARG_WITH([queue-size],
 159             AS_HELP_STRING([--with-queue-size=SIZE],
 160             [Set the XCB buffer queue size (default is 16384)]),
 161             [xcb_queue_buffer_size="$withval"],
 162             [xcb_queue_buffer_size=16384])
 163 AC_DEFINE_UNQUOTED(XCB_QUEUE_BUFFER_SIZE, [$xcb_queue_buffer_size],
 164                    [XCB buffer queue size])
 165
 166 dnl check for the sockaddr_un.sun_len member
 167 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 168                 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN,1,[Have the sockaddr_un.sun_len member.])],
 169                 [],
 170                 [ #include <sys/types.h>
 171                   #include <sys/un.h>
 172                 ])
 173
 174 dnl check for support for Solaris Trusted Extensions
 175 AC_CHECK_HEADERS([tsol/label.h])
 176 AC_CHECK_FUNCS([is_system_labeled])
 177
 178 dnl check for IOV_MAX, and fall back to UIO_MAXIOV on BSDish systems
 179 AC_CHECK_DECL([IOV_MAX], [],
 180               [AC_CHECK_DECL([UIO_MAXIOV], [AC_DEFINE([IOV_MAX], [UIO_MAXIOV])],
 181                                            [AC_DEFINE([IOV_MAX], [16], [Define if not provided by <limits.h>])],
 182                                            [[#include <sys/uio.h>]])],
 183               [[#include <limits.h>]])
 184
 185 xcbincludedir='${includedir}/xcb'
 186 AC_SUBST(xcbincludedir)
 187
 188 XCB_CHECK_VISIBILITY()
 189
 190 AC_CHECK_FUNC(getaddrinfo, [AC_DEFINE(HAVE_GETADDRINFO, 1, [getaddrinfo() function is available])], )
 191
 192 case $host_os in
 193         # darwin through Snow Leopard has poll() but can't be used to poll character devices.
 194         darwin@<:@789@:>@*|darwin10*) ;;
 195         darwin*)
 196                 _ac_xorg_macosx_version_min=""
 197                 if echo $CPPFLAGS $CFLAGS | grep -q mmacosx-version-min ; then
 198                         _ac_xorg_macosx_version_min=`echo $CPPFLAGS $CFLAGS | sed 's/^.*-mmacosx-version-min=\(@<:@^ @:>@*\).*$/\1/'`
 199                 else
 200                         _ac_xorg_macosx_version_min=$MACOSX_DEPLOYMENT_TARGET
 201                 fi
 202                 case $_ac_xorg_macosx_version_min in
 203                         10.@<:@0123456@:>@|10.@<:@0123456@:>@.*) ;;
 204                         *)
 205                                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 206                         ;;
 207                 esac
 208                 unset _ac_xorg_macosx_version_min
 209                 ;;
 210         *)
 211                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 212         ;;
 213 esac
 214
 215 XCB_EXTENSION(Composite, "yes")
 216 XCB_EXTENSION(Damage, "yes")
 217 XCB_EXTENSION(DPMS, "yes")
 218 XCB_EXTENSION(DRI2, "yes")
 219 XCB_EXTENSION(DRI3, "$sendfds")
 220 XCB_EXTENSION(GLX, "yes")
 221 XCB_EXTENSION(Present, "yes")
 222 XCB_EXTENSION(RandR, "yes")
 223 XCB_EXTENSION(Record, "yes")
 224 XCB_EXTENSION(Render, "yes")
 225 XCB_EXTENSION(Resource, "yes")
 226 XCB_EXTENSION(Screensaver, "yes")
 227 XCB_EXTENSION(Shape, "yes")
 228 XCB_EXTENSION(Shm, "yes")
 229 XCB_EXTENSION(Sync, "yes")
 230 XCB_EXTENSION(Xevie, "yes")
 231 XCB_EXTENSION(XFixes, "yes")
 232 XCB_EXTENSION(XFree86-DRI, "yes")
 233 XCB_EXTENSION(Xinerama, "yes")
 234 XCB_EXTENSION(XInput, "no")
 235 XCB_EXTENSION(XKB, "yes")
 236 XCB_EXTENSION(Xprint, "yes")
 237 XCB_EXTENSION(SELinux, "no")
 238 XCB_EXTENSION(XTest, "yes")
 239 XCB_EXTENSION(Xv, "yes")
 240 XCB_EXTENSION(XvMC, "yes")
 241
 242 AC_ARG_WITH(launchd, AS_HELP_STRING([--with-launchd], [Build with support for Apple's launchd (default: auto)]), [LAUNCHD=$withval], [LAUNCHD=auto])
 243 if test "x$LAUNCHD" = xauto; then
 244         unset LAUNCHD
 245         AC_CHECK_PROG(LAUNCHD, [launchd], [yes], [no], [$PATH$PATH_SEPARATOR/sbin])
 246 fi
 247
 248 if test "x$LAUNCHD" = xyes ; then
 249         AC_DEFINE(HAVE_LAUNCHD, 1, [launchd support available])
 250 fi
 251
 252 AC_CONFIG_FILES([
 253 Makefile
 254 doc/Makefile
 255 man/Makefile
 256 src/Makefile
 257 tests/Makefile
 258 ])
 259
 260 AC_CONFIG_FILES([
 261 xcb.pc
 262 xcb-composite.pc
 263 xcb-damage.pc
 264 xcb-dpms.pc
 265 xcb-dri2.pc
 266 xcb-dri3.pc
 267 xcb-glx.pc
 268 xcb-present.pc
 269 xcb-randr.pc
 270 xcb-record.pc
 271 xcb-render.pc
 272 xcb-res.pc
 273 xcb-screensaver.pc
 274 xcb-shape.pc
 275 xcb-shm.pc
 276 xcb-sync.pc
 277 xcb-xevie.pc
 278 xcb-xf86dri.pc
 279 xcb-xfixes.pc
 280 xcb-xinerama.pc
 281 xcb-xinput.pc
 282 xcb-xkb.pc
 283 xcb-xprint.pc
 284 xcb-xselinux.pc
 285 xcb-xtest.pc
 286 xcb-xv.pc
 287 xcb-xvmc.pc
 288 ])
 289
 290 AC_CONFIG_FILES([
 291 doc/xcb.doxygen
 292 ])
 293
 294 AC_OUTPUT
 295
 296 dnl Configuration output
 297
 298 echo ""
 299 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 300 echo ""
 301 echo "  Configuration"
 302 echo "    XDM support.........: ${have_xdmcp}"
 303 echo "    sendmsg fd passing..: ${sendfds}"
 304 echo "    Build unit tests....: ${HAVE_CHECK}"
 305 echo "      with html results.: ${HTML_CHECK_RESULT}"
 306 echo "    XCB buffer size.....: ${xcb_queue_buffer_size}"
 307 echo ""
 308 echo "  X11 extensions"
 309 echo "    Composite...........: ${BUILD_COMPOSITE}"
 310 echo "    Damage..............: ${BUILD_DAMAGE}"
 311 echo "    Dpms................: ${BUILD_DPMS}"
 312 echo "    Dri2................: ${BUILD_DRI2}"
 313 echo "    Dri3................: ${BUILD_DRI3}"
 314 echo "    Glx.................: ${BUILD_GLX}"
 315 echo "    Randr...............: ${BUILD_RANDR}"
 316 echo "    Record..............: ${BUILD_RECORD}"
 317 echo "    Render..............: ${BUILD_RENDER}"
 318 echo "    Resource............: ${BUILD_RESOURCE}"
 319 echo "    Screensaver.........: ${BUILD_SCREENSAVER}"
 320 echo "    selinux.............: ${BUILD_SELINUX}"
 321 echo "    Shape...............: ${BUILD_SHAPE}"
 322 echo "    Shm.................: ${BUILD_SHM}"
 323 echo "    Sync................: ${BUILD_SYNC}"
 324 echo "    Xevie...............: ${BUILD_XEVIE}"
 325 echo "    Xfixes..............: ${BUILD_XFIXES}"
 326 echo "    Xfree86-dri.........: ${BUILD_XFREE86_DRI}"
 327 echo "    xinerama............: ${BUILD_XINERAMA}"
 328 echo "    xinput..............: ${BUILD_XINPUT}"
 329 echo "    xkb.................: ${BUILD_XKB}"
 330 echo "    xprint..............: ${BUILD_XPRINT}"
 331 echo "    xtest...............: ${BUILD_XTEST}"
 332 echo "    xv..................: ${BUILD_XV}"
 333 echo "    xvmc................: ${BUILD_XVMC}"
 334 echo ""
 335 echo "  Used CFLAGS:"
 336 echo "    CPPFLAGS............: ${CPPFLAGS}"
 337 echo "    CFLAGS..............: ${CFLAGS}"
 338 echo "    Warning CFLAGS......: ${BASE_CFLAGS}"
 339 echo ""
 340 echo "  Installation:"
 341 echo "    Prefix..............: ${prefix}"
 342 echo ""