git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Initialize Autoconf
   5 AC_PREREQ([2.60])
   6 AC_INIT([libxcb],
   7         1.10,
   8         [xcb@lists.freedesktop.org])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AC_CONFIG_SRCDIR([xcb.pc.in])
  12
  13 # Initialize Automake
  14 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  15
  16 # Set common system defines for POSIX extensions, such as _GNU_SOURCE
  17 # Must be called before any macros that run the compiler (like AC_PROG_LIBTOOL)
  18 # to avoid autoconf errors.
  19 AC_USE_SYSTEM_EXTENSIONS
  20
  21 AM_PATH_PYTHON([2.6])
  22
  23 PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
  24 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
  25
  26 AC_CONFIG_HEADERS([src/config.h])
  27
  28 AC_LIBTOOL_WIN32_DLL
  29 AC_PROG_LIBTOOL
  30
  31 # Require xorg-macros minimum of 1.18 - Initial version
  32 m4_ifndef([XORG_MACROS_VERSION],
  33           [m4_fatal([must install xorg-macros 1.18 or later before running autoconf/autogen])])
  34 XORG_MACROS_VERSION(1.18)
  35 XORG_DEFAULT_OPTIONS
  36
  37 XSLTPROC=no
  38 HTML_CHECK_RESULT=no
  39 if test x"$HAVE_CHECK" = xyes; then
  40         AC_PATH_PROG(XSLTPROC, xsltproc, no)
  41         if test x"$XSLTPROC" != xno; then
  42                 HTML_CHECK_RESULT=yes
  43         fi
  44 fi
  45 AC_SUBST(HTML_CHECK_RESULT)
  46
  47 # Checks for pkg-config packages
  48 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.10)
  49 NEEDED="pthread-stubs xau >= 0.99.2"
  50 PKG_CHECK_MODULES(NEEDED, $NEEDED)
  51
  52 have_xdmcp="no"
  53 PKG_CHECK_MODULES(XDMCP, xdmcp,
  54         AC_CHECK_LIB(Xdmcp, XdmcpWrap,
  55                 [
  56                 AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
  57                 NEEDED="$NEEDED xdmcp"
  58                 have_xdmcp="yes"
  59                 ],
  60                 [
  61                 XDMCP_CFLAGS=
  62                 XDMCP_LIBS=
  63                 ], [$XDMCP_LIBS]),
  64         [AC_MSG_RESULT(no)])
  65
  66 AC_SUBST(NEEDED)
  67
  68 # Find the xcb-proto protocol descriptions
  69 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  70 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  71 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  72 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  73
  74 # Find the xcb-proto version
  75 XCBPROTO_VERSION=`$PKG_CONFIG --modversion xcb-proto`
  76 AC_SUBST(XCBPROTO_VERSION)
  77
  78 # Find the xcbgen Python package
  79 AC_MSG_CHECKING(XCBPROTO_XCBPYTHONDIR)
  80 XCBPROTO_XCBPYTHONDIR=`$PKG_CONFIG --variable=pythondir xcb-proto`
  81 AC_MSG_RESULT($XCBPROTO_XCBPYTHONDIR)
  82 AC_SUBST(XCBPROTO_XCBPYTHONDIR)
  83
  84 AC_HEADER_STDC
  85 AC_SEARCH_LIBS(getaddrinfo, socket)
  86 AC_SEARCH_LIBS(connect, socket)
  87
  88 AC_ARG_ENABLE(sendfds, AS_HELP_STRING([--disable-sendfds], [Support FD passing (default: auto)]),
  89               [sendfds=$enableval], [sendfds=auto])
  90
  91 case x$sendfds in
  92 xauto)
  93         AC_SEARCH_LIBS(sendmsg, socket, [sendfds="yes"], [sendfds="no"])
  94         ;;
  95 esac
  96
  97 # XPG4v2/UNIX95 added msg_control - check to see if we need to define
  98 # _XOPEN_SOURCE to get it (such as on Solaris)
  99 AC_CHECK_MEMBER([struct msghdr.msg_control], [], [],
 100                  [
 101 AC_INCLUDES_DEFAULT
 102 #include <sys/socket.h>
 103                  ])
 104 # First try for Solaris in C99 compliant mode, which requires XPG6/UNIX03
 105 if test "x$ac_cv_member_struct_msghdr_msg_control" = xno; then
 106     unset ac_cv_member_struct_msghdr_msg_control
 107     AC_MSG_NOTICE([trying again with _XOPEN_SOURCE=600])
 108     AC_CHECK_MEMBER([struct msghdr.msg_control],
 109                     [AC_DEFINE([_XOPEN_SOURCE], [600],
 110                        [Defined if needed to expose struct msghdr.msg_control])
 111                     ], [], [
 112 #define _XOPEN_SOURCE 600
 113 AC_INCLUDES_DEFAULT
 114 #include <sys/socket.h>
 115                      ])
 116 fi
 117 # If that didn't work, fall back to XPG5/UNIX98 with C89
 118 if test "x$ac_cv_member_struct_msghdr_msg_control" = xno; then
 119     unset ac_cv_member_struct_msghdr_msg_control
 120     AC_MSG_NOTICE([trying again with _XOPEN_SOURCE=500])
 121     AC_CHECK_MEMBER([struct msghdr.msg_control],
 122                     [AC_DEFINE([_XOPEN_SOURCE], [500],
 123                        [Defined if needed to expose struct msghdr.msg_control])
 124                     ], [sendfds="no"], [
 125 #define _XOPEN_SOURCE 500
 126 AC_INCLUDES_DEFAULT
 127 #include <sys/socket.h>
 128                      ])
 129 fi
 130
 131 case x$sendfds in
 132 xyes)
 133         AC_DEFINE([HAVE_SENDMSG],1,[Define if your platform supports sendmsg])
 134         ;;
 135 esac
 136
 137 have_win32="no"
 138 lt_enable_auto_import=""
 139 case $host_os in
 140 mingw*)
 141         have_win32="yes"
 142         lt_enable_auto_import="-Wl,--enable-auto-import"
 143         ;;
 144 linux*)
 145         AC_DEFINE([HAVE_ABSTRACT_SOCKETS], 1, [Define if your platform supports abstract sockets])
 146         ;;
 147 esac
 148
 149 AC_SUBST(lt_enable_auto_import)
 150 AM_CONDITIONAL([XCB_HAVE_WIN32], [test "x${have_win32}" = "xyes"])
 151
 152 dnl define buffer queue size
 153 AC_ARG_WITH([queue-size],
 154             AC_HELP_STRING([--with-queue-size=SIZE],
 155             [Set the XCB buffer queue size (default is 16384)]),
 156             [xcb_queue_buffer_size="$withval"],
 157             [xcb_queue_buffer_size=16384])
 158 AC_DEFINE_UNQUOTED(XCB_QUEUE_BUFFER_SIZE, [$xcb_queue_buffer_size],
 159                    [XCB buffer queue size])
 160
 161 dnl check for the sockaddr_un.sun_len member
 162 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 163                 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN,1,[Have the sockaddr_un.sun_len member.])],
 164                 [],
 165                 [ #include <sys/types.h>
 166                   #include <sys/un.h>
 167                 ])
 168
 169 dnl check for support for Solaris Trusted Extensions
 170 AC_CHECK_HEADERS([tsol/label.h])
 171 AC_CHECK_FUNCS([is_system_labeled])
 172
 173 dnl check for IOV_MAX, and fall back to UIO_MAXIOV on BSDish systems
 174 AC_CHECK_DECL([IOV_MAX], [],
 175               [AC_CHECK_DECL([UIO_MAXIOV], [AC_DEFINE([IOV_MAX], [UIO_MAXIOV])],
 176                                            [AC_DEFINE([IOV_MAX], [16], [Define if not provided by <limits.h>])],
 177                                            [[#include <sys/uio.h>]])],
 178               [[#include <limits.h>]])
 179
 180 xcbincludedir='${includedir}/xcb'
 181 AC_SUBST(xcbincludedir)
 182
 183 XCB_CHECK_VISIBILITY()
 184
 185 XCB_CHECK_DOXYGEN()
 186
 187 AC_CHECK_FUNC(getaddrinfo, [AC_DEFINE(HAVE_GETADDRINFO, 1, [getaddrinfo() function is available])], )
 188
 189 case $host_os in
 190         # darwin through Snow Leopard has poll() but can't be used to poll character devices.
 191         darwin@<:@789@:>@*|darwin10*) ;;
 192         darwin*)
 193                 _ac_xorg_macosx_version_min=""
 194                 if echo $CPPFLAGS $CFLAGS | grep -q mmacosx-version-min ; then
 195                         _ac_xorg_macosx_version_min=`echo $CPPFLAGS $CFLAGS | sed 's/^.*-mmacosx-version-min=\(@<:@^ @:>@*\).*$/\1/'`
 196                 else
 197                         _ac_xorg_macosx_version_min=$MACOSX_DEPLOYMENT_TARGET
 198                 fi
 199                 case $_ac_xorg_macosx_version_min in
 200                         10.@<:@0123456@:>@|10.@<:@0123456@:>@.*) ;;
 201                         *)
 202                                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 203                         ;;
 204                 esac
 205                 unset _ac_xorg_macosx_version_min
 206                 ;;
 207         *)
 208                 AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
 209         ;;
 210 esac
 211
 212 XCB_EXTENSION(Composite, "yes")
 213 XCB_EXTENSION(Damage, "yes")
 214 XCB_EXTENSION(DPMS, "yes")
 215 XCB_EXTENSION(DRI2, "yes")
 216 XCB_EXTENSION(DRI3, "$sendfds")
 217 XCB_EXTENSION(GLX, "yes")
 218 XCB_EXTENSION(Present, "yes")
 219 XCB_EXTENSION(RandR, "yes")
 220 XCB_EXTENSION(Record, "yes")
 221 XCB_EXTENSION(Render, "yes")
 222 XCB_EXTENSION(Resource, "yes")
 223 XCB_EXTENSION(Screensaver, "yes")
 224 XCB_EXTENSION(Shape, "yes")
 225 XCB_EXTENSION(Shm, "yes")
 226 XCB_EXTENSION(Sync, "yes")
 227 XCB_EXTENSION(Xevie, "yes")
 228 XCB_EXTENSION(XFixes, "yes")
 229 XCB_EXTENSION(XFree86-DRI, "yes")
 230 XCB_EXTENSION(Xinerama, "yes")
 231 XCB_EXTENSION(XInput, "no")
 232 XCB_EXTENSION(XKB, "yes")
 233 XCB_EXTENSION(Xprint, "yes")
 234 XCB_EXTENSION(SELinux, "no")
 235 XCB_EXTENSION(XTest, "yes")
 236 XCB_EXTENSION(Xv, "yes")
 237 XCB_EXTENSION(XvMC, "yes")
 238
 239 AC_ARG_WITH(launchd, AS_HELP_STRING([--with-launchd], [Build with support for Apple's launchd (default: auto)]), [LAUNCHD=$withval], [LAUNCHD=auto])
 240 if test "x$LAUNCHD" = xauto; then
 241         unset LAUNCHD
 242         AC_CHECK_PROG(LAUNCHD, [launchd], [yes], [no], [$PATH$PATH_SEPARATOR/sbin])
 243 fi
 244
 245 if test "x$LAUNCHD" = xyes ; then
 246         AC_DEFINE(HAVE_LAUNCHD, 1, [launchd support available])
 247 fi
 248
 249 AC_CONFIG_FILES([
 250 Makefile
 251 doc/Makefile
 252 src/Makefile
 253 tests/Makefile
 254 ])
 255
 256 AC_CONFIG_FILES([
 257 xcb.pc
 258 xcb-composite.pc
 259 xcb-damage.pc
 260 xcb-dpms.pc
 261 xcb-dri2.pc
 262 xcb-dri3.pc
 263 xcb-glx.pc
 264 xcb-present.pc
 265 xcb-randr.pc
 266 xcb-record.pc
 267 xcb-render.pc
 268 xcb-res.pc
 269 xcb-screensaver.pc
 270 xcb-shape.pc
 271 xcb-shm.pc
 272 xcb-sync.pc
 273 xcb-xevie.pc
 274 xcb-xf86dri.pc
 275 xcb-xfixes.pc
 276 xcb-xinerama.pc
 277 xcb-xinput.pc
 278 xcb-xkb.pc
 279 xcb-xprint.pc
 280 xcb-xselinux.pc
 281 xcb-xtest.pc
 282 xcb-xv.pc
 283 xcb-xvmc.pc
 284 ])
 285
 286 AC_CONFIG_FILES([
 287 doc/xcb.doxygen
 288 ])
 289
 290 AC_OUTPUT
 291
 292 dnl Configuration output
 293
 294 echo ""
 295 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 296 echo ""
 297 echo "  Configuration"
 298 echo "    XDM support.........: ${have_xdmcp}"
 299 echo "    sendmsg fd passing..: ${sendfds}"
 300 echo "    Build unit tests....: ${HAVE_CHECK}"
 301 echo "      with html results.: ${HTML_CHECK_RESULT}"
 302 echo "    XCB buffer size.....: ${xcb_queue_buffer_size}"
 303 echo ""
 304 echo "  X11 extensions"
 305 echo "    Composite...........: ${BUILD_COMPOSITE}"
 306 echo "    Damage..............: ${BUILD_DAMAGE}"
 307 echo "    Dpms................: ${BUILD_DPMS}"
 308 echo "    Dri2................: ${BUILD_DRI2}"
 309 echo "    Dri3................: ${BUILD_DRI3}"
 310 echo "    Glx.................: ${BUILD_GLX}"
 311 echo "    Randr...............: ${BUILD_RANDR}"
 312 echo "    Record..............: ${BUILD_RECORD}"
 313 echo "    Render..............: ${BUILD_RENDER}"
 314 echo "    Resource............: ${BUILD_RESOURCE}"
 315 echo "    Screensaver.........: ${BUILD_SCREENSAVER}"
 316 echo "    selinux.............: ${BUILD_SELINUX}"
 317 echo "    Shape...............: ${BUILD_SHAPE}"
 318 echo "    Shm.................: ${BUILD_SHM}"
 319 echo "    Sync................: ${BUILD_SYNC}"
 320 echo "    Xevie...............: ${BUILD_XEVIE}"
 321 echo "    Xfixes..............: ${BUILD_XFIXES}"
 322 echo "    Xfree86-dri.........: ${BUILD_XFREE86_DRI}"
 323 echo "    xinerama............: ${BUILD_XINERAMA}"
 324 echo "    xinput..............: ${BUILD_XINPUT}"
 325 echo "    xkb.................: ${BUILD_XKB}"
 326 echo "    xprint..............: ${BUILD_XPRINT}"
 327 echo "    xtest...............: ${BUILD_XTEST}"
 328 echo "    xv..................: ${BUILD_XV}"
 329 echo "    xvmc................: ${BUILD_XVMC}"
 330 echo ""
 331 echo "  Used CFLAGS:"
 332 echo "    CPPFLAGS............: ${CPPFLAGS}"
 333 echo "    CFLAGS..............: ${CFLAGS}"
 334 echo "    Warning CFLAGS......: ${BASE_CFLAGS}"
 335 echo ""
 336 echo "  Installation:"
 337 echo "    Prefix..............: ${prefix}"
 338 echo ""