git.demorecorder.com Git - free-sw/xcb/libxcb/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.57)
   5 AC_INIT([libXCB],
   6         0.9,
   7         [xcb@lists.freedesktop.org])
   8 AC_CONFIG_SRCDIR([xcb.pc.in])
   9 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  10
  11 dnl This ifdef has no useful effect prior to automake 1.9, but in 1.9
  12 dnl it allows the user to not have check.m4 installed.
  13 m4_ifdef([AM_PATH_CHECK],[
  14 AM_PATH_CHECK(0.8.2, [HAVE_CHECK=true], [HAVE_CHECK=false])
  15 ])
  16 AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xtrue)
  17
  18 AC_CONFIG_HEADERS([src/config.h])
  19
  20 AC_PROG_LIBTOOL
  21 AC_PROG_CC
  22
  23 AC_PATH_PROG(XSLTPROC, xsltproc, no)
  24 if test "$XSLTPROC" = "no"; then
  25    AC_MSG_ERROR([XCB requires xsltproc.])
  26 fi
  27
  28 HTML_CHECK_RESULT=false
  29 if test x"$HAVE_CHECK" = xtrue; then
  30         if test x"$XSLTPROC" != xno; then
  31                 HTML_CHECK_RESULT=true
  32         fi
  33 fi
  34 AC_SUBST(HTML_CHECK_RESULT)
  35
  36 # Checks for pkg-config packages
  37 PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 0.9)
  38 PKG_CHECK_MODULES(XPROTO, xproto)
  39 PKG_CHECK_MODULES(XAU, xau)
  40
  41 # Find the xcb-proto protocol descriptions
  42 AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
  43 XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
  44 AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
  45 AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
  46
  47 AC_HEADER_STDC
  48 AC_FUNC_ALLOCA
  49 AC_SEARCH_LIBS(gethostbyname, nsl)
  50 AC_SEARCH_LIBS(connect, socket)
  51
  52 xcbincludedir='${includedir}/X11/XCB'
  53 AC_SUBST(xcbincludedir)
  54
  55 AC_ARG_WITH(opt,
  56 AC_HELP_STRING([--with-opt],       [compile with reasonable optimizations])
  57 AC_HELP_STRING([--with-opt=FLAGS], [compile with specified FLAGS])
  58 AC_HELP_STRING([--with-opt=small], [compile for smallest code])
  59 AC_HELP_STRING([--without-opt],    [compile without optimization (default)]),
  60 [
  61         case "$withval" in
  62         yes)
  63                 COPTFLAGS="-O3"
  64                 ;;
  65         small)
  66                 COPTFLAGS="-Os -fomit-frame-pointer -DNDEBUG"
  67                 ;;
  68         no)
  69                 COPTFLAGS=""
  70                 ;;
  71         *)
  72                 COPTFLAGS="$withval"
  73                 ;;
  74         esac
  75 ])
  76 AC_CACHE_CHECK([what compiler optimizations to apply], [COPTFLAGS], [COPTFLAGS=""])
  77 AC_SUBST(COPTFLAGS)
  78
  79 AC_ARG_WITH(debug,
  80 AC_HELP_STRING([--with-debug],       [compile with debugging (default)])
  81 AC_HELP_STRING([--with-debug=FLAGS], [compile with specified debugging FLAGS])
  82 AC_HELP_STRING([--without-debug],    [compile without debugging]),
  83 [
  84         case "$withval" in
  85         yes)
  86                 CDEBUGFLAGS="-g"
  87                 ;;
  88         no)
  89                 CDEBUGFLAGS=""
  90                 ;;
  91         *)
  92                 CDEBUGFLAGS="$withval"
  93                 ;;
  94         esac
  95 ])
  96 AC_CACHE_CHECK([what debugging options to apply], [CDEBUGFLAGS], [CDEBUGFLAGS="-g"])
  97 AC_SUBST(CDEBUGFLAGS)
  98
  99 CWARNFLAGS="-Wall -pedantic -Wpointer-arith \
 100         -Wstrict-prototypes -Wmissing-declarations -Wnested-externs"
 101 AC_SUBST(CWARNFLAGS)
 102
 103 AC_CONFIG_FILES([Makefile src/Makefile tests/Makefile])
 104 AC_CONFIG_FILES([xcb.pc])
 105
 106 AC_OUTPUT